configure.ac

   1 # configure.in  for GPGME
   2 # Copyright (C) 2000 Werner Koch (dd9jn)
   3 # Copyright (C) 2001, 2002 g10 Code GmbH
   4 #
   5 # This file is part of GPGME.
   6 #
   7 # GPGME is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # GPGME is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
  20
  21 # (Process this file with autoconf to produce a configure script.)
  22
  23 # Version numbers (Remember to change them just before a release.)
  24 #   (Code changed:                      REVISION++)
  25 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
  26 #   (Interfaces added:                  AGE++)
  27 #   (Interfaces removed:                AGE=0)
  28 #
  29 AC_INIT(gpgme, 0.3.5-cvs-2002-03-10, [gnupg-devel@gnupg.org])
  30 LIBGPGME_LT_CURRENT=7
  31 LIBGPGME_LT_AGE=1
  32 LIBGPGME_LT_REVISION=0
  33 NEED_GPG_VERSION=1.0.6d
  34 NEED_GPGSM_VERSION=0.3.1
  35 ##############################################
  36 AC_PREREQ(2.52)
  37 AC_REVISION($Revision$)
  38
  39 PACKAGE=$PACKAGE_NAME
  40 VERSION=$PACKAGE_VERSION
  41
  42 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
  43 AM_CONFIG_HEADER(config.h)
  44 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  45 AM_MAINTAINER_MODE
  46
  47 AC_PROG_CC
  48
  49
  50 AC_SUBST(LIBGPGME_LT_CURRENT)
  51 AC_SUBST(LIBGPGME_LT_AGE)
  52 AC_SUBST(LIBGPGME_LT_REVISION)
  53 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION")
  54 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION")
  55
  56 AC_SUBST(PACKAGE)
  57 AC_SUBST(VERSION)
  58 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
  59 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
  60
  61 dnl Don't default to build static libs.
  62 dnl AC_DISABLE_STATIC
  63 AC_PROG_LIBTOOL
  64
  65 GPG_DEFAULT=no
  66 GPGSM_DEFAULT=no
  67 component_system=None
  68 case "${target}" in
  69     *-*-mingw32* | i?86-emx-os2 | i?86-*-os2*emx | i?86-*-msdosdjgpp* )
  70         # special stuff for Windoze NT
  71         # OS/2 with the EMX environment
  72         # DOS with the DJGPP environment
  73         AC_DEFINE(HAVE_DRIVE_LETTERS)
  74         AC_DEFINE(HAVE_DOSISH_SYSTEM)
  75         have_dosish_system=yes
  76         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
  77         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
  78         #component_system='COM+'
  79         ;;
  80     *)
  81 dnl     # XXX: Probably use exec-prefix here?
  82 dnl     GPG_DEFAULT='/usr/bin/gpg'
  83 dnl     GPGSM_DEFAULT='/usr/bin/gpgsm'
  84         ;;
  85 esac
  86 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = "yes")
  87
  88 dnl
  89 dnl Checks for libraries.
  90 dnl
  91
  92 dnl FIXME: check whether Bonobo is installed
  93
  94 dnl
  95 dnl Checks for header files.
  96 dnl
  97
  98 dnl
  99 dnl Checks for typedefs and structures.
 100 dnl
 101 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
 102 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
 103 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
 104 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
 105 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 106
 107 dnl We should not use them in this software;
 108 dnl However jnlib/types.h needs them - so we take the easy way.
 109 AC_CHECK_SIZEOF(unsigned short)
 110 AC_CHECK_SIZEOF(unsigned int)
 111 AC_CHECK_SIZEOF(unsigned long)
 112
 113 dnl
 114 dnl Checks for compiler features.
 115 dnl
 116
 117 if test "$GCC" = yes; then
 118     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
 119 fi
 120
 121 dnl
 122 dnl Checks for library functions.
 123 dnl
 124 dnl These are needed by libjnlib
 125 AC_CHECK_FUNCS(memicmp stpcpy strlwr strtoul memmove stricmp)
 126
 127 # asprintf() is at least used in assuan
 128 AC_REPLACE_FUNCS(vasprintf)
 129 # Note: fopencokie is only a dummy stub and not used.
 130 #       However some code in assuan/ links against it.
 131 AC_REPLACE_FUNCS(fopencookie)
 132
 133
 134 dnl We use jnlib, so tell other modules about it
 135 AC_DEFINE(HAVE_JNLIB_LOGGING, 1,
 136         [Defined if jnlib style logging fucntions are available.])
 137
 138 dnl
 139 dnl Checks for system services
 140 dnl
 141
 142 NO_OVERRIDE=no
 143 AC_ARG_WITH(gpg,
 144             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
 145             GPG=$withval, NO_OVERRIDE=yes)
 146 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
 147   GPG=
 148   NO_OVERRIDE=yes
 149   if test "$cross_compiling" != "yes"; then
 150     AC_PATH_PROG(GPG, gpg)
 151   fi
 152   if test -z "$GPG"; then
 153     GPG="$GPG_DEFAULT"
 154   fi
 155 fi
 156 if test "$GPG" = no; then
 157   if test "$NO_OVERRIDE" = "yes"; then
 158     if test "$cross_compiling" != "yes"; then
 159       AC_MSG_WARN([Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it])
 160     else
 161       AC_MSG_ERROR([Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH])
 162     fi
 163   fi
 164 else
 165   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG")
 166   AC_SUBST(GPG)
 167 fi
 168 AM_CONDITIONAL(RUN_GPG_TESTS,
 169   [test "$cross_compiling" != "yes" && test -n "$GPG" && test -r "$GPG"])
 170 AC_SUBST(GPG_PATH)
 171
 172 NO_OVERRIDE=no
 173 AC_ARG_WITH(gpgsm,
 174             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
 175             GPGSM=$withval, NO_OVERRIDE=yes)
 176 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
 177   GPGSM=
 178   NO_OVERRIDE=yes
 179   if test "$cross_compiling" != "yes"; then
 180     AC_PATH_PROG(GPGSM, gpgsm)
 181   fi
 182   if test -z "$GPGSM"; then
 183     GPGSM="$GPGSM_DEFAULT"
 184   fi
 185 fi
 186 if test "$GPGSM" = no; then
 187   if test "$NO_OVERRIDE" = "yes"; then
 188     if test "$cross_compiling" != "yes"; then
 189       AC_MSG_WARN([Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it])
 190     else
 191       AC_MSG_ERROR([Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH])
 192     fi
 193   fi
 194 else
 195   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM")
 196   AC_SUBST(GPGSM)
 197 fi
 198 AM_CONDITIONAL(RUN_GPGSM_TESTS,
 199   [test "$cross_compiling" != "yes" && test -n "$GPGSM" && test -r "$GPGSM"])
 200
 201 dnl FIXME: Only build if supported.
 202 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
 203
 204 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
 205 AM_CONDITIONAL(BUILD_BONOBO,  test "$component_system" = "Bonobo")
 206
 207 GPGMEPLUG=no
 208 AC_ARG_ENABLE(gpgmeplug,
 209             AC_HELP_STRING([--enable-gpgmeplug], [build GPGME Crypt Plug-In]),
 210             GPGMEPLUG=$enableval)
 211 AM_CONDITIONAL(BUILD_GPGMEPLUG, test "$GPGMEPLUG" = "yes")
 212
 213 dnl Make the version number in gpgme/gpgme.h the same as the one here.
 214 dnl (this is easier than to have a *.in file just for one substitution)
 215 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
 216
 217 dnl Substitution used for gpgme-config
 218 GPGME_LIBS="-L${libdir} -lgpgme"
 219 GPGME_CFLAGS=""
 220 AC_SUBST(GPGME_LIBS)
 221 AC_SUBST(GPGME_CFLAGS)
 222
 223 dnl
 224 dnl Create config files
 225 dnl
 226
 227 AC_CONFIG_FILES(Makefile assuan/Makefile jnlib/Makefile gpgme/Makefile
 228                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
 229                 doc/Makefile
 230                 bonobo/Makefile complus/Makefile gpgmeplug/Makefile)
 231 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
 232 AC_OUTPUT
 233
 234 echo "
 235         GPGME v${VERSION} has been configured as follows:
 236
 237         GnuPG version: min. $NEED_GPG_VERSION
 238         GnuPG path:    $GPG
 239
 240         GpgSM version: min. $NEED_GPGSM_VERSION
 241         GpgSM path:    $GPGSM
 242
 243         GPGME CryptPlug: $GPGMEPLUG
 244 "