configure.ac

   1 # configure.in  for GPGME
   2 # Copyright (C) 2000 Werner Koch (dd9jn)
   3 # Copyright (C) 2001, 2002 g10 Code GmbH
   4 #
   5 # This file is part of GPGME.
   6 #
   7 # GPGME is free software; you can redistribute it and/or modify
   8 # it under the terms of the GNU General Public License as published by
   9 # the Free Software Foundation; either version 2 of the License, or
  10 # (at your option) any later version.
  11 #
  12 # GPGME is distributed in the hope that it will be useful,
  13 # but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 # MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 # GNU General Public License for more details.
  16 #
  17 # You should have received a copy of the GNU General Public License
  18 # along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
  20
  21 # (Process this file with autoconf to produce a configure script.)
  22
  23 # Version number: Remember to change it immediately *after* a release.
  24 AC_INIT(gpgme, 0.3.11, [bug-gpgme@gnupg.org])
  25 # LT Version numbers, remember to change them just *before* a release.
  26 #   (Code changed:                      REVISION++)
  27 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
  28 #   (Interfaces added:                  AGE++)
  29 #   (Interfaces removed:                AGE=0)
  30 #
  31 LIBGPGME_LT_CURRENT=9
  32 LIBGPGME_LT_AGE=3
  33 LIBGPGME_LT_REVISION=1
  34 NEED_GPG_VERSION=1.0.7
  35 NEED_GPGSM_VERSION=0.3.8
  36 ##############################################
  37 AC_PREREQ(2.52)
  38 AC_REVISION($Revision$)
  39
  40 PACKAGE=$PACKAGE_NAME
  41 VERSION=$PACKAGE_VERSION
  42
  43 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
  44 AM_CONFIG_HEADER(config.h)
  45 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  46 AM_MAINTAINER_MODE
  47
  48 AH_VERBATIM([_GNU_SOURCE],
  49 [/* Enable GNU extensions on systems that have them.  */
  50 #ifndef _GNU_SOURCE
  51 # define _GNU_SOURCE
  52 #endif])
  53
  54 AH_VERBATIM([_REENTRANT],
  55 [/* To allow the use of GPGME in multithreaded programs we have to use
  56   special features from the library.
  57   IMPORTANT: gpgme is not yet fully reentrant and you should use it
  58   only from one thread.  */
  59 #ifndef _REENTRANT
  60 # define _REENTRANT 1
  61 #endif])
  62
  63
  64 AC_PROG_CC
  65
  66
  67 AC_SUBST(LIBGPGME_LT_CURRENT)
  68 AC_SUBST(LIBGPGME_LT_AGE)
  69 AC_SUBST(LIBGPGME_LT_REVISION)
  70 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
  71                                      [Min. needed GnuPG version.])
  72 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
  73                                        [Min. needed GPGSM version.])
  74
  75 AC_SUBST(PACKAGE)
  76 AC_SUBST(VERSION)
  77 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
  78 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
  79
  80 dnl Don't default to build static libs.
  81 dnl AC_DISABLE_STATIC
  82 AC_PROG_LIBTOOL
  83
  84 GPG_DEFAULT=no
  85 GPGSM_DEFAULT=no
  86 component_system=None
  87 case "${target}" in
  88     *-*-mingw32* | i?86-emx-os2 | i?86-*-os2*emx | i?86-*-msdosdjgpp* )
  89         # special stuff for Windoze NT
  90         # OS/2 with the EMX environment
  91         # DOS with the DJGPP environment
  92         AC_DEFINE(HAVE_DRIVE_LETTERS, ,
  93                   [Defined if we run on some of the PCDOS like systems (DOS,
  94                    Windoze, OS/2) with special properties like no file modes.])
  95         AC_DEFINE(HAVE_DOSISH_SYSTEM, ,
  96                   [Defined if the filesystem uses driver letters.])
  97         have_dosish_system=yes
  98         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
  99         GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
 100         #component_system='COM+'
 101         ;;
 102     *)
 103         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
 104         if test "$have_pth" = yes; then
 105           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
 106           CFLAGS="$CFLAGS $PTH_CFLAGS"
 107         fi
 108         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
 109         if test "$have_pthread" = yes; then
 110           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
 111         fi
 112
 113 dnl     # XXX: Probably use exec-prefix here?
 114 dnl     GPG_DEFAULT='/usr/bin/gpg'
 115 dnl     GPGSM_DEFAULT='/usr/bin/gpgsm'
 116         ;;
 117 esac
 118 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = "yes")
 119 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
 120 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
 121
 122 dnl
 123 dnl Checks for libraries.
 124 dnl
 125
 126 dnl FIXME: check whether Bonobo is installed
 127
 128 dnl
 129 dnl Checks for header files.
 130 dnl
 131
 132 dnl
 133 dnl Checks for typedefs and structures.
 134 dnl
 135 GNUPG_CHECK_TYPEDEF(byte, HAVE_BYTE_TYPEDEF)
 136 GNUPG_CHECK_TYPEDEF(ushort, HAVE_USHORT_TYPEDEF)
 137 GNUPG_CHECK_TYPEDEF(ulong, HAVE_ULONG_TYPEDEF)
 138 GNUPG_CHECK_TYPEDEF(u16, HAVE_U16_TYPEDEF)
 139 GNUPG_CHECK_TYPEDEF(u32, HAVE_U32_TYPEDEF)
 140
 141 AC_CHECK_SIZEOF(unsigned int)
 142
 143 dnl
 144 dnl Checks for compiler features.
 145 dnl
 146
 147 if test "$GCC" = yes; then
 148     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
 149 fi
 150
 151 dnl
 152 dnl Checks for library functions.
 153 dnl
 154
 155 AC_REPLACE_FUNCS(stpcpy)
 156
 157 AC_REPLACE_FUNCS(vasprintf)
 158 if test "$ac_cv_func_vasprintf" != yes; then
 159   GNUPG_CHECK_VA_COPY
 160 fi
 161
 162
 163
 164 # Note: fopencokie is only a dummy stub and not used.
 165 #       However some code in assuan/ links against it.
 166 AC_REPLACE_FUNCS(fopencookie)
 167
 168
 169
 170 dnl
 171 dnl Checks for system services
 172 dnl
 173
 174 NO_OVERRIDE=no
 175 AC_ARG_WITH(gpg,
 176             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
 177             GPG=$withval, NO_OVERRIDE=yes)
 178 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
 179   GPG=
 180   NO_OVERRIDE=yes
 181   if test "$cross_compiling" != "yes"; then
 182     AC_PATH_PROG(GPG, gpg)
 183   fi
 184   if test -z "$GPG"; then
 185     GPG="$GPG_DEFAULT"
 186   fi
 187 fi
 188 if test "$GPG" = no; then
 189   if test "$NO_OVERRIDE" = "yes"; then
 190     if test "$cross_compiling" != "yes"; then
 191       AC_MSG_WARN([Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it])
 192     else
 193       AC_MSG_ERROR([Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH])
 194     fi
 195   fi
 196 else
 197   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
 198   AC_SUBST(GPG)
 199 fi
 200 AM_CONDITIONAL(RUN_GPG_TESTS,
 201   [test "$cross_compiling" != "yes" && test -n "$GPG" && test -r "$GPG"])
 202 AC_SUBST(GPG_PATH)
 203
 204 NO_OVERRIDE=no
 205 AC_ARG_WITH(gpgsm,
 206             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
 207             GPGSM=$withval, NO_OVERRIDE=yes)
 208 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
 209   GPGSM=
 210   NO_OVERRIDE=yes
 211   if test "$cross_compiling" != "yes"; then
 212     AC_PATH_PROG(GPGSM, gpgsm)
 213   fi
 214   if test -z "$GPGSM"; then
 215     GPGSM="$GPGSM_DEFAULT"
 216   fi
 217 fi
 218 if test "$GPGSM" = no; then
 219   if test "$NO_OVERRIDE" = "yes"; then
 220     if test "$cross_compiling" != "yes"; then
 221       AC_MSG_WARN([Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it])
 222     else
 223       AC_MSG_ERROR([Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH])
 224     fi
 225   fi
 226 else
 227   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
 228   AC_SUBST(GPGSM)
 229 fi
 230 AM_CONDITIONAL(RUN_GPGSM_TESTS,
 231   [test "$cross_compiling" != "yes" && test -n "$GPGSM" && test -r "$GPGSM"])
 232
 233 dnl FIXME: Only build if supported.
 234 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
 235
 236 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
 237 AM_CONDITIONAL(BUILD_BONOBO,  test "$component_system" = "Bonobo")
 238
 239 GPGMEPLUG=no
 240 AC_ARG_ENABLE(gpgmeplug,
 241             AC_HELP_STRING([--enable-gpgmeplug], [build GPGME Crypt Plug-In]),
 242             GPGMEPLUG=$enableval)
 243 AM_CONDITIONAL(BUILD_GPGMEPLUG, test "$GPGMEPLUG" = "yes")
 244
 245 dnl Make the version number in gpgme/gpgme.h the same as the one here.
 246 dnl (this is easier than to have a *.in file just for one substitution)
 247 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
 248
 249 dnl Substitution used for gpgme-config
 250 GPGME_CONFIG_LIBS="-lgpgme"
 251 GPGME_CONFIG_CFLAGS=""
 252 AC_SUBST(GPGME_CONFIG_LIBS)
 253 AC_SUBST(GPGME_CONFIG_CFLAGS)
 254
 255 dnl
 256 dnl Create config files
 257 dnl
 258
 259 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
 260                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
 261                 doc/Makefile
 262                 bonobo/Makefile complus/Makefile gpgmeplug/Makefile)
 263 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
 264 AC_OUTPUT
 265
 266 echo "
 267         GPGME v${VERSION} has been configured as follows:
 268
 269         GnuPG version: min. $NEED_GPG_VERSION
 270         GnuPG path:    $GPG
 271
 272         GpgSM version: min. $NEED_GPGSM_VERSION
 273         GpgSM path:    $GPGSM
 274
 275         GPGME CryptPlug: $GPGMEPLUG
 276 "