app-xemacs/ebuild-mode/ebuild-mode-1.50.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Emacs modes for editing ebuilds and other Gentoo specific files"
   7 HOMEPAGE="https://wiki.gentoo.org/wiki/Project:Emacs"
   8 SRC_URI="https://dev.gentoo.org/~ulm/emacs/${P}.tar.xz"
   9
  10 LICENSE="GPL-2+"
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~hppa ~x86"
  13
  14 RDEPEND=">=app-editors/xemacs-21.4.20-r5
  15         app-xemacs/sh-script"
  16 BDEPEND="${RDEPEND}"
  17
  18 src_compile() {
  19         local XEMACS="${EPREFIX}/usr/bin/xemacs"
  20
  21         "${XEMACS}" -batch -q --no-site-file \
  22                 -eval "(add-to-list 'load-path \".\")" \
  23                 -f batch-byte-compile \
  24                 ebuild-mode.el gentoo-newsitem-mode.el || die
  25
  26         "${XEMACS}" -batch -q --no-site-file \
  27                 -eval "(setq autoload-package-name \"${PN}\")" \
  28                 -eval "(setq generated-autoload-file \"${S}/auto-autoloads.el\")" \
  29                 -l autoload -f batch-update-autoloads \
  30                 ebuild-mode.el gentoo-newsitem-mode.el || die
  31 }
  32
  33 src_install() {
  34         insinto /usr/share/xemacs/site-packages/lisp/${PN}
  35         doins *.el *.elc
  36 }