app-vim/vimoutliner/vimoutliner-0.4.0_p20180301-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit python-single-r1 vim-plugin vcs-snapshot
   9
  10 # Commit Date: 1 Mar 2018
  11 COMMIT="4f12628247940d98eedd594961695dc504261058"
  12
  13 DESCRIPTION="Vim plugin for easy and fast outlining"
  14 HOMEPAGE="https://github.com/vimoutliner/vimoutliner"
  15 SRC_URI="https://github.com/vimoutliner/vimoutliner/archive/${COMMIT}.tar.gz -> ${P}.tar.gz"
  16
  17 LICENSE="GPL-3"
  18 KEYWORDS="~amd64 ~ia64 ~ppc ~sparc ~x86"
  19
  20 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  21
  22 VIM_PLUGIN_HELPFILES="vimoutliner"
  23 VIM_PLUGIN_MESSAGES="filetype"
  24
  25 RDEPEND="${PYTHON_DEPS}
  26         $(python_gen_cond_dep '
  27                 dev-python/autopep8[${PYTHON_MULTI_USEDEP}]
  28         ')"
  29 DEPEND="${RDEPEND}"
  30
  31 src_prepare() {
  32         default
  33
  34         sed -i -e '1s:^:#!/usr/bin/python\n:' vimoutliner/scripts/otl2latex/otl2latex.py || die
  35         find "${S}" -type f -exec chmod a+r {} \; || die
  36 }
  37
  38 src_compile() {
  39         local pyscript _pyscript
  40         for pyscript in $(find "${S}" -type f -name \*.py); do
  41                 _pyscript=$(basename "${pyscript}")
  42                 [ ${_pyscript} == "otl.py" ] && continue
  43                 python_fix_shebang -q "${pyscript}"
  44         done
  45 }