app-text/zathura/zathura-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit meson virtualx
   7
   8 DESCRIPTION="A highly customizable and functional document viewer"
   9 HOMEPAGE="http://pwmt.org/projects/zathura/"
  10
  11 if [[ ${PV} == *9999 ]]; then
  12         inherit git-r3
  13         EGIT_REPO_URI="https://git.pwmt.org/pwmt/${PN}.git"
  14         EGIT_BRANCH="develop"
  15 else
  16         SRC_URI="https://github.com/pwmt/zathura/archive/${PV}.tar.gz -> ${P}.tar.gz"
  17         KEYWORDS="~amd64 ~arm ~x86 ~amd64-linux ~x86-linux"
  18 fi
  19
  20 LICENSE="ZLIB"
  21 SLOT="0"
  22 IUSE="doc +magic seccomp sqlite synctex test"
  23
  24 RESTRICT="!test? ( test )"
  25
  26 DEPEND=">=dev-libs/girara-0.3.3
  27         >=dev-libs/glib-2.50:2
  28         >=sys-devel/gettext-0.19.8
  29         x11-libs/cairo[X]
  30         >=x11-libs/gtk+-3.22:3
  31         magic? ( sys-apps/file )
  32         seccomp? ( sys-libs/libseccomp )
  33         sqlite? ( >=dev-db/sqlite-3.5.9:3 )
  34         synctex? ( app-text/texlive-core )"
  35
  36 RDEPEND="${DEPEND}"
  37
  38 BDEPEND="doc? ( dev-python/sphinx )
  39         test? ( dev-libs/appstream-glib
  40                 dev-libs/check )
  41         virtual/pkgconfig"
  42
  43 src_configure() {
  44         local emesonargs=(
  45                 -Dconvert-icon=disabled
  46                 -Dmagic=$(usex magic enabled disabled)
  47                 -Dmanpages=$(usex doc enabled disabled)
  48                 -Dseccomp=$(usex seccomp enabled disabled)
  49                 -Dsqlite=$(usex sqlite enabled disabled)
  50                 -Dsynctex=$(usex synctex enabled disabled)
  51                 )
  52         meson_src_configure
  53 }
  54
  55 src_test() {
  56         virtx meson_src_test
  57 }