app-text/yodl/yodl-3.05.00.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit toolchain-funcs
   8
   9 DESCRIPTION="Your Own Document Language: a pre-document language and tools to process it"
  10 HOMEPAGE="http://yodl.sourceforge.net/"
  11 SRC_URI="mirror://sourceforge/${PN}/${P/-/_}.orig.tar.gz"
  12
  13 LICENSE="GPL-3"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="doc"
  17
  18 DEPEND="dev-util/icmake"
  19
  20 src_prepare() {
  21         sed -e "/DOC.* =/s/yodl\(-doc\)\?/${PF}/" \
  22                 -e "/COMPILER =/s/gcc/$(tc-getCC)/" \
  23                 -e "/CXX =/s/g++/$(tc-getCXX)/" \
  24                 -i INSTALL.im || die
  25
  26         sed -e "s/ar ru/$(tc-getAR) ru/" \
  27                 -e "s/ranlib/$(tc-getRANLIB)/" \
  28                 -i icmake/stdcompile || die
  29 }
  30
  31 src_compile() {
  32         ./build programs || die
  33         ./build macros || die
  34         ./build man || die
  35         use doc && { ./build manual || die ; }
  36 }
  37
  38 src_install() {
  39         ./build install programs "${ED}" || die
  40         ./build install macros "${ED}" || die
  41         ./build install man "${ED}" || die
  42         ./build install docs "${ED}" || die
  43         use doc && { ./build install manual "${ED}" || die ; }
  44 }