app-text/tree/tree-1.7.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit toolchain-funcs flag-o-matic bash-completion-r1
   6
   7 DESCRIPTION="Lists directories recursively, and produces an indented listing of files"
   8 HOMEPAGE="http://mama.indstate.edu/users/ice/tree/"
   9 SRC_URI="ftp://mama.indstate.edu/linux/tree/${P}.tgz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~riscv ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~x64-macos ~x86-macos"
  14 IUSE=""
  15
  16 RDEPEND="!=sci-biology/meme-4.8.1"
  17 DEPEND=""
  18
  19 src_prepare() {
  20         sed -i -e 's:LINUX:__linux__:' tree.c || die
  21         mv doc/tree.1.fr doc/tree.fr.1
  22         if use !elibc_glibc ; then
  23                 # 433972, also previously done only for elibc_uclibc
  24                 sed -i -e '/^OBJS=/s/$/ strverscmp.o/' Makefile || die
  25         fi
  26         default
  27 }
  28
  29 src_compile() {
  30         append-lfs-flags
  31         emake \
  32                 CC="$(tc-getCC)" \
  33                 CFLAGS="${CFLAGS} ${CPPFLAGS}" \
  34                 LDFLAGS="${LDFLAGS}"
  35 }
  36
  37 src_install() {
  38         dobin tree
  39         doman doc/tree*.1
  40         einstalldocs
  41         newbashcomp "${FILESDIR}"/${PN}.bashcomp ${PN}
  42 }