app-text/sablotron/sablotron-1.0.3-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit autotools
   7
   8 MY_PN="Sablot"
   9 MY_P="${MY_PN}-${PV}"
  10 S=${WORKDIR}/${MY_P}
  11
  12 DESCRIPTION="An XSLT Parser in C++"
  13 HOMEPAGE="http://www.gingerall.org/sablotron.html"
  14 SRC_URI="http://download-1.gingerall.cz/download/sablot/${MY_P}.tar.gz"
  15
  16 # Sablotron can optionally be built under GPL, using MPL for now
  17 LICENSE="MPL-1.1"
  18 SLOT="0"
  19 KEYWORDS="~alpha amd64 arm hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  20 IUSE="perl"
  21
  22 RDEPEND=">=dev-libs/expat-1.95.6-r1"
  23 DEPEND="${RDEPEND}
  24         >=dev-perl/XML-Parser-2.3"
  25
  26 PATCHES=( "${FILESDIR}/1.0.3-libsablot-expat.patch" )
  27
  28 src_prepare() {
  29         default
  30         sed -i configure.in -e 's|AM_CONFIG_HEADER|AC_CONFIG_HEADERS|g' || die
  31         eautoreconf
  32         elibtoolize
  33 }
  34
  35 src_configure() {
  36         econf \
  37                 $(use_enable perl perlconnect) \
  38                 --with-html-dir="${EPREFIX}"/usr/share/doc/${PF}/html
  39 }
  40
  41 src_install() {
  42         emake DESTDIR="${D}" install
  43         dodoc README README_JS RELEASE src/TODO
  44 }