app-text/qpdf/qpdf-9.1.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 DESCRIPTION="Command-line tool for structural, content-preserving transformation of PDF files"
   7 HOMEPAGE="http://qpdf.sourceforge.net/"
   8 SRC_URI="mirror://sourceforge/qpdf/${P}.tar.gz"
   9
  10 LICENSE="|| ( Apache-2.0 Artistic-2 )"
  11
  12 # subslot = libqpdf soname version
  13 SLOT="0/26"
  14
  15 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~ppc64 ~s390 ~sparc ~x86 ~amd64-linux ~x86-linux ~m68k-mint ~sparc-solaris"
  16 IUSE="doc examples perl static-libs test"
  17
  18 RESTRICT="!test? ( test )"
  19
  20 CDEPEND="
  21         net-libs/gnutls:0=
  22         sys-libs/zlib
  23         virtual/jpeg:0=
  24 "
  25 DEPEND="${CDEPEND}
  26         test? (
  27                 sys-apps/diffutils
  28                 media-libs/tiff
  29                 app-text/ghostscript-gpl[tiff]
  30         )
  31 "
  32 # Only need perl for the installed tools.
  33 RDEPEND="${CDEPEND}
  34         perl? ( >=dev-lang/perl-5.8 )
  35 "
  36
  37 DOCS=( ChangeLog README.md TODO )
  38
  39 src_configure() {
  40         local myeconfargs=(
  41                 --disable-implicit-crypto
  42                 --enable-crypto-gnutls
  43                 --enable-crypto-native
  44                 --with-default-crypto=gnutls
  45                 $(use_enable static-libs static)
  46                 $(use_enable test test-compare-images)
  47         )
  48         CONFIG_SHELL=/bin/bash econf "${myeconfargs[@]}"
  49 }
  50
  51 src_install() {
  52         default
  53
  54         if ! use perl ; then
  55                 rm "${ED}"/usr/bin/fix-qdf || die
  56                 rm "${ED}"/usr/share/man/man1/fix-qdf.1 || die
  57         fi
  58
  59         if use examples ; then
  60                 dobin examples/build/.libs/*
  61         fi
  62
  63         find "${ED}" -type f -name '*.la' -delete || die
  64 }