app-text/ots/ots-0.5.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit autotools eutils
   6
   7 DESCRIPTION="Open source Text Summarizer, as used in newer releases of abiword and kword"
   8 HOMEPAGE="http://libots.sourceforge.net/"
   9 SRC_URI="mirror://sourceforge/libots/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~alpha amd64 ~arm hppa ~mips ppc ppc64 ~sparc x86"
  14 IUSE=""
  15
  16 RDEPEND="
  17         dev-libs/glib:2
  18         >=dev-libs/libxml2-2.4.23
  19         >=dev-libs/popt-1.5
  20 "
  21 DEPEND="${RDEPEND}
  22         virtual/pkgconfig
  23 "
  24
  25 DOCS="AUTHORS BUGS ChangeLog HACKING NEWS README TODO"
  26
  27 src_prepare() {
  28         # ugly ugly hack, kick upstream to fix its packaging
  29         touch "${S}"/gtk-doc.make
  30
  31         epatch "${FILESDIR}"/${P}-math.patch
  32         epatch "${FILESDIR}"/${P}-automake-1.13.patch
  33         epatch "${FILESDIR}"/${P}-fix-installation.patch
  34         epatch "${FILESDIR}"/${P}-fix-underlinking.patch
  35         eautoreconf
  36 }
  37
  38 src_configure() {
  39         # bug 97448
  40         econf \
  41                 --disable-gtk-doc \
  42                 --disable-static
  43 }
  44
  45 src_compile() {
  46         # parallel make fails, bug 112932
  47         emake -j1
  48 }
  49
  50 src_install() {
  51         default
  52         prune_libtool_files
  53         rm -rf "${D}"/usr/share/doc/libots
  54 }