app-text/openjade/openjade-1.3.2-r6.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 inherit autotools sgml-catalog eutils flag-o-matic multilib
   8
   9 DESCRIPTION="Jade is an implementation of DSSSL - an ISO standard for formatting SGML and XML documents"
  10 HOMEPAGE="http://openjade.sourceforge.net"
  11 SRC_URI="mirror://sourceforge/openjade/${P}.tar.gz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="static-libs"
  17
  18 RDEPEND="app-text/sgml-common
  19         >=app-text/opensp-1.5.1"
  20 DEPEND="dev-lang/perl
  21         ${RDEPEND}"
  22
  23 src_prepare() {
  24         epatch "${FILESDIR}"/${P}-deplibs.patch
  25         epatch "${FILESDIR}"/${P}-ldflags.patch
  26         epatch "${FILESDIR}"/${P}-msggen.pl.patch
  27         epatch "${FILESDIR}"/${P}-respect-ldflags.patch
  28         epatch "${FILESDIR}"/${P}-libosp-la.patch
  29         epatch "${FILESDIR}"/${P}-gcc46.patch
  30         epatch "${FILESDIR}"/${P}-darwin.patch
  31
  32         # Please note!  Opts are disabled.  If you know what you're doing
  33         # feel free to remove this line.  It may cause problems with
  34         # docbook-sgml-utils among other things.
  35         #ALLOWED_FLAGS="-O -O1 -O2 -pipe -g -march"
  36         strip-flags
  37
  38         # Default CFLAGS and CXXFLAGS is -O2 but this make openjade segfault
  39         # on hppa. Using -O1 works fine. So I force it here.
  40         use hppa && replace-flags -O2 -O1
  41
  42         ln -s config/configure.in configure.ac || die
  43         cp "${FILESDIR}"/${P}-acinclude.m4 acinclude.m4 || die
  44         rm config/missing || die
  45
  46         AT_NOEAUTOMAKE=yes
  47         eautoreconf
  48
  49         SGML_PREFIX="${EPREFIX}"/usr/share/sgml
  50 }
  51
  52 src_configure() {
  53         # We need Prefix env, bug #287358
  54         export CONFIG_SHELL="${CONFIG_SHELL:-${BASH}}"
  55         econf \
  56                 --enable-http \
  57                 --enable-default-catalog="${EPREFIX}"/etc/sgml/catalog \
  58                 --enable-default-search-path="${EPREFIX}"/usr/share/sgml \
  59                 --enable-splibdir="${EPREFIX}"/usr/$(get_libdir) \
  60                 --libdir="${EPREFIX}"/usr/$(get_libdir) \
  61                 --datadir="${EPREFIX}"/usr/share/sgml/${P} \
  62                 $(use_enable static-libs static)
  63 }
  64
  65 src_compile() {
  66         # Bug 412725.
  67         unset INCLUDE
  68
  69         emake -j1 SHELL="${BASH}"
  70 }
  71
  72 src_install() {
  73         insinto /usr/$(get_libdir)
  74
  75         make DESTDIR="${D}" \
  76                 SHELL="${BASH}" \
  77                 libdir="${EPREFIX}"/usr/$(get_libdir) \
  78                 install install-man
  79
  80         prune_libtool_files
  81
  82         dosym openjade  /usr/bin/jade
  83         dosym onsgmls   /usr/bin/nsgmls
  84         dosym osgmlnorm /usr/bin/sgmlnorm
  85         dosym ospam     /usr/bin/spam
  86         dosym ospent    /usr/bin/spent
  87         dosym osx       /usr/bin/sgml2xml
  88
  89         insinto /usr/share/sgml/${P}/
  90         doins dsssl/builtins.dsl
  91
  92         echo 'SYSTEM "builtins.dsl" "builtins.dsl"' > ${ED}/usr/share/sgml/${P}/catalog
  93         insinto /usr/share/sgml/${P}/dsssl
  94         doins dsssl/{dsssl.dtd,style-sheet.dtd,fot.dtd}
  95         newins "${FILESDIR}"/${P}.dsssl-catalog catalog
  96 # Breaks sgml2xml among other things
  97 #       insinto /usr/share/sgml/${P}/unicode
  98 #       doins unicode/{catalog,unicode.sd,unicode.syn,gensyntax.pl}
  99         insinto /usr/share/sgml/${P}/pubtext
 100         doins pubtext/*
 101
 102         dodoc NEWS README VERSION
 103         dohtml doc/*.htm
 104
 105         insinto /usr/share/doc/${PF}/jadedoc
 106         doins jadedoc/*.htm
 107         insinto /usr/share/doc/${PF}/jadedoc/images
 108         doins jadedoc/images/*
 109 }
 110
 111 sgml-catalog_cat_include "/etc/sgml/${P}.cat" \
 112         "/usr/share/sgml/openjade-${PV}/catalog"
 113 sgml-catalog_cat_include "/etc/sgml/${P}.cat" \
 114         "/usr/share/sgml/openjade-${PV}/dsssl/catalog"
 115 sgml-catalog_cat_include "/etc/sgml/sgml-docbook.cat" \
 116         "/etc/sgml/${P}.cat"