app-text/mftrace/mftrace-1.2.19-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7
   8 inherit python-single-r1 toolchain-funcs
   9
  10 DESCRIPTION="Traces TeX fonts to PFA or PFB fonts (formerly pktrace)"
  11 HOMEPAGE="http://lilypond.org/mftrace/"
  12 SRC_URI="http://lilypond.org/downloads/sources/mftrace/${P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 KEYWORDS="~amd64 ~hppa ~ppc ~x86"
  16 # SLOT 1 was used in pktrace ebuild
  17 SLOT="1"
  18 IUSE="test truetype"
  19 RESTRICT="!test? ( test )"
  20 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  21
  22 RDEPEND=">=app-text/t1utils-1.25
  23         media-gfx/potrace
  24         truetype? ( media-gfx/fontforge )
  25         virtual/latex-base
  26         ${PYTHON_DEPS}"
  27 DEPEND="${RDEPEND}
  28         test? ( media-gfx/fontforge )"
  29
  30 src_configure() {
  31         tc-export CC
  32         econf \
  33                 --datadir="$(python_get_sitedir)"
  34 }
  35
  36 src_compile() {
  37         emake CFLAGS="-Wall ${CFLAGS}"
  38 }
  39
  40 src_install() {
  41         default
  42         python_optimize
  43 }