app-text/libmwaw/libmwaw-9999.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [[ ${PV} = 9999 ]]; then
   7         EGIT_REPO_URI="https://git.code.sf.net/p/libmwaw/libmwaw"
   8         inherit autotools git-r3
   9 else
  10         SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
  11         KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86"
  12 fi
  13
  14 DESCRIPTION="Library parsing many pre-OSX MAC text formats"
  15 HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
  16
  17 LICENSE="LGPL-2.1"
  18 SLOT="0"
  19 IUSE="doc static-libs tools"
  20
  21 BDEPEND="
  22         sys-devel/libtool
  23         virtual/pkgconfig
  24         doc? ( app-doc/doxygen )
  25 "
  26 DEPEND="
  27         dev-libs/librevenge
  28         sys-libs/zlib
  29 "
  30 RDEPEND="${DEPEND}"
  31
  32 src_prepare() {
  33         default
  34         [[ ${PV} == 9999 ]] && eautoreconf
  35 }
  36
  37 src_configure() {
  38         # zip is hard enabled as the zlib is dep on the rdeps anyway
  39         local myeconfargs=(
  40                 --enable-zip
  41                 --disable-werror
  42                 $(use_with doc docs)
  43                 $(use_enable static-libs static)
  44                 $(use_enable tools)
  45         )
  46         econf "${myeconfargs[@]}"
  47 }
  48
  49 src_install() {
  50         default
  51         find "${D}" -name '*.la' -delete || die
  52 }