app-text/libmwaw/libmwaw-0.3.8.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 EGIT_REPO_URI="git://git.code.sf.net/p/libmwaw/libmwaw"
   8 [[ ${PV} == 9999 ]] && inherit autotools git-r3
   9
  10 DESCRIPTION="Library parsing many pre-OSX MAC text formats"
  11 HOMEPAGE="https://sourceforge.net/p/libmwaw/wiki/Home/"
  12 [[ ${PV} == 9999 ]] || SRC_URI="mirror://sourceforge/${PN}/${P}.tar.xz"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16
  17 [[ ${PV} == 9999 ]] || \
  18 KEYWORDS="amd64 ~arm x86"
  19
  20 IUSE="doc static-libs"
  21
  22 RDEPEND="
  23         dev-libs/librevenge
  24         dev-libs/libxml2
  25         sys-libs/zlib
  26 "
  27 DEPEND="${RDEPEND}
  28         dev-libs/boost
  29         sys-devel/libtool
  30         virtual/pkgconfig
  31         doc? ( app-doc/doxygen )
  32 "
  33
  34 src_prepare() {
  35         default
  36         [[ ${PV} == 9999 ]] && eautoreconf
  37 }
  38
  39 src_configure() {
  40         # zip is hard enabled as the zlib is dep on the rdeps anyway
  41         econf \
  42                 --enable-zip \
  43                 --disable-werror \
  44                 --with-sharedptr=boost \
  45                 $(use_with doc docs) \
  46                 $(use_enable static-libs static)
  47 }
  48
  49 src_install() {
  50         default
  51         find "${D}" -name '*.la' -delete || die
  52 }