app-text/libgxps/libgxps-0.2.3.2.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GNOME2_LA_PUNT="yes"
   7 GCONF_DEBUG="yes"
   8
   9 inherit gnome2
  10
  11 DESCRIPTION="Library for handling and rendering XPS documents"
  12 HOMEPAGE="https://wiki.gnome.org/Projects/libgxps"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="alpha amd64 arm ia64 ppc ppc64 sparc x86"
  17 IUSE="+introspection jpeg lcms static-libs tiff"
  18
  19 RDEPEND="
  20         >=app-arch/libarchive-2.8
  21         >=dev-libs/glib-2.24:2
  22         media-libs/freetype:2
  23         media-libs/libpng:0
  24         >=x11-libs/cairo-1.10[svg]
  25         introspection? ( >=dev-libs/gobject-introspection-0.10.1:= )
  26         jpeg? ( virtual/jpeg:0 )
  27         lcms? ( media-libs/lcms:2 )
  28         tiff? ( media-libs/tiff:0[zlib] )
  29 "
  30 DEPEND="${RDEPEND}
  31         app-text/docbook-xsl-stylesheets
  32         dev-libs/libxslt
  33         dev-util/gtk-doc-am
  34         virtual/pkgconfig
  35 "
  36
  37 # There is no automatic test suite, only an interactive test application
  38 RESTRICT="test"
  39
  40 src_configure() {
  41         gnome2_src_configure \
  42                 --enable-man \
  43                 --disable-test \
  44                 $(use_enable introspection) \
  45                 $(use_with jpeg libjpeg) \
  46                 $(use_with lcms liblcms2) \
  47                 $(use_enable static-libs static) \
  48                 $(use_with tiff libtiff)
  49 }