app-text/libetonyek/libetonyek-9999.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 EGIT_REPO_URI="https://anongit.freedesktop.org/git/libreoffice/libetonyek.git"
   7 [[ ${PV} == 9999 ]] && inherit autotools git-r3
   8
   9 DESCRIPTION="Library parsing Apple Keynote presentations"
  10 HOMEPAGE="https://wiki.documentfoundation.org/DLP/Libraries/libetonyek"
  11 [[ ${PV} == 9999 ]] || SRC_URI="https://dev-www.libreoffice.org/src/libetonyek/${P}.tar.xz"
  12
  13 LICENSE="|| ( GPL-2+ LGPL-2.1 MPL-1.1 )"
  14 SLOT="0"
  15 [[ ${PV} == 9999 ]] || \
  16 KEYWORDS="~amd64 ~arm ~x86"
  17 IUSE="doc static-libs test"
  18
  19 RDEPEND="
  20         app-text/liblangtag
  21         dev-libs/librevenge
  22         dev-libs/libxml2
  23         sys-libs/zlib
  24 "
  25 DEPEND="${RDEPEND}
  26         dev-libs/boost
  27         >=dev-util/mdds-1.2.2:1
  28         media-libs/glm
  29         sys-devel/libtool
  30         virtual/pkgconfig
  31         doc? ( app-doc/doxygen )
  32         test? ( dev-util/cppunit )
  33 "
  34
  35 pkg_pretend() {
  36         if [[ $(gcc-major-version) -lt 4 ]] || {
  37                 [[ $(gcc-major-version) -eq 4 && $(gcc-minor-version) -lt 8 ]]; }
  38         then
  39                 eerror "Compilation with gcc older than 4.8 is not supported"
  40                 die "Too old gcc found."
  41         fi
  42 }
  43
  44 src_prepare() {
  45         default
  46         [[ -d m4 ]] || mkdir "m4"
  47         [[ ${PV} == 9999 ]] && eautoreconf
  48 }
  49
  50 src_configure() {
  51         econf \
  52                 --disable-werror \
  53                 $(use_with doc docs) \
  54                 $(use_enable static-libs static) \
  55                 $(use_enable test tests) \
  56                 --with-mdds=1.2
  57 }
  58
  59 src_install() {
  60         default
  61         find "${D}" -name '*.la' -delete || die
  62 }