app-text/kbibtex/kbibtex-0.9.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 ECM_HANDBOOK="optional"
   7 ECM_TEST="true"
   8 KFMIN=5.60.0
   9 QTMIN=5.12.3
  10 inherit ecm kde.org
  11
  12 DESCRIPTION="BibTeX editor to edit bibliographies used with LaTeX"
  13 HOMEPAGE="https://kde.org/applications/education/org.kde.kbibtex
  14 https://userbase.kde.org/KBibTeX"
  15
  16 if [[ ${KDE_BUILD_TYPE} != live ]]; then
  17         SRC_URI="mirror://kde/stable/KBibTeX/${PV}/${P}.tar.xz"
  18         KEYWORDS="amd64 ~x86"
  19 fi
  20
  21 LICENSE="GPL-2"
  22 SLOT="5"
  23 IUSE="webengine zotero"
  24
  25 DEPEND="
  26         app-text/poppler[qt5]
  27         dev-libs/icu:=
  28         >=dev-qt/qtconcurrent-${QTMIN}:5
  29         >=dev-qt/qtdbus-${QTMIN}:5
  30         >=dev-qt/qtgui-${QTMIN}:5
  31         >=dev-qt/qtnetwork-${QTMIN}:5
  32         >=dev-qt/qtwidgets-${QTMIN}:5
  33         >=dev-qt/qtxml-${QTMIN}:5
  34         >=dev-qt/qtxmlpatterns-${QTMIN}:5
  35         >=kde-frameworks/kcompletion-${KFMIN}:5
  36         >=kde-frameworks/kconfig-${KFMIN}:5
  37         >=kde-frameworks/kconfigwidgets-${KFMIN}:5
  38         >=kde-frameworks/kcoreaddons-${KFMIN}:5
  39         >=kde-frameworks/kcrash-${KFMIN}:5
  40         >=kde-frameworks/ki18n-${KFMIN}:5
  41         >=kde-frameworks/kiconthemes-${KFMIN}:5
  42         >=kde-frameworks/kio-${KFMIN}:5
  43         >=kde-frameworks/kitemviews-${KFMIN}:5
  44         >=kde-frameworks/kjobwidgets-${KFMIN}:5
  45         >=kde-frameworks/kparts-${KFMIN}:5
  46         >=kde-frameworks/kservice-${KFMIN}:5
  47         >=kde-frameworks/ktexteditor-${KFMIN}:5
  48         >=kde-frameworks/ktextwidgets-${KFMIN}:5
  49         >=kde-frameworks/kwallet-${KFMIN}:5
  50         >=kde-frameworks/kwidgetsaddons-${KFMIN}:5
  51         >=kde-frameworks/kxmlgui-${KFMIN}:5
  52         virtual/tex-base
  53         webengine? ( >=dev-qt/qtwebengine-${QTMIN}:5[widgets] )
  54         zotero? (
  55                 app-crypt/qca[qt5(+)]
  56                 dev-libs/qoauth:5
  57         )
  58 "
  59 RDEPEND="${DEPEND}
  60         dev-tex/bibtex2html
  61 "
  62
  63 RESTRICT+=" test"
  64
  65 src_configure() {
  66         local mycmakeargs=(
  67                 -DCMAKE_DISABLE_FIND_PACKAGE_Qt5WebKitWidgets=ON
  68                 $(cmake_use_find_package webengine Qt5WebEngineWidgets)
  69                 $(cmake_use_find_package zotero Qca-qt5)
  70         )
  71
  72         ecm_src_configure
  73 }
  74
  75 pkg_postinst() {
  76         ecm_pkg_postinst
  77
  78         if ! has_version "kde-apps/okular:${SLOT}" ; then
  79                 elog "For PDF or PostScript document preview support, please install kde-apps/okular:${SLOT}"
  80         fi
  81 }