app-text/gtkspell/gtkspell-3.0.10.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2 vala
   7
   8 DESCRIPTION="Spell checking widget for GTK"
   9 HOMEPAGE="http://gtkspell.sourceforge.net/"
  10 MY_P="${PN}3-${PV}"
  11 SRC_URI="mirror://sourceforge/project/${PN}/${PV}/${MY_P}.tar.xz"
  12
  13 LICENSE="GPL-2+"
  14 SLOT="3/0"
  15 KEYWORDS="~alpha amd64 arm arm64 ~hppa ~ia64 ~mips ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-macos ~x86-solaris"
  16 IUSE="+introspection vala"
  17 REQUIRED_USE="vala? ( introspection )"
  18
  19 RDEPEND="
  20         app-text/enchant:2
  21         app-text/iso-codes
  22         dev-libs/glib:2
  23         x11-libs/gtk+:3[introspection?]
  24         >=x11-libs/pango-1.8.0[introspection?]
  25         introspection? ( >=dev-libs/gobject-introspection-1.30:= )
  26 "
  27 DEPEND="${RDEPEND}
  28         >=dev-util/gtk-doc-am-1.17
  29         >=dev-util/intltool-0.35.0
  30         virtual/pkgconfig
  31         vala? ( $(vala_depend) )
  32 "
  33
  34 S="${WORKDIR}/${MY_P}"
  35
  36 src_prepare() {
  37         use vala && vala_src_prepare
  38         gnome2_src_prepare
  39 }
  40
  41 src_configure() {
  42         gnome2_src_configure \
  43                 --disable-static \
  44                 $(use_enable introspection) \
  45                 $(use_enable vala)
  46 }