app-text/dvipdfm/dvipdfm-0.13.2d-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=3
   5 inherit eutils
   6
   7 DESCRIPTION="DVI to PDF translator"
   8 SRC_URI="http://gaspra.kettering.edu/dvipdfm/${P}.tar.gz"
   9 HOMEPAGE="http://gaspra.kettering.edu/dvipdfm/"
  10 LICENSE="GPL-2"
  11
  12 KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 s390 sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~x64-solaris ~x86-solaris"
  13 SLOT="0"
  14 IUSE=""
  15
  16 DEPEND="!>=app-text/tetex-2
  17         >=media-libs/libpng-1.2.1
  18         >=sys-libs/zlib-1.1.4
  19         !app-text/ptex
  20         virtual/latex-base"
  21 RDEPEND="${DEPEND}"
  22
  23 S=${WORKDIR}/${PN}
  24
  25 src_prepare() {
  26         epatch "${FILESDIR}"/${P}-libpng14.patch
  27 }
  28
  29 src_install () {
  30         einstall || die "einstall failed!"
  31
  32         # Install .map and .enc files to correct locations, bug #200956
  33         dodir /usr/share/texmf/fonts/map/dvipdfm/base
  34
  35         for i in cmr.map psbase14.map lw35urw.map lw35urwa.map t1fonts.map; do
  36                 mv "${ED}usr/share/texmf/dvipdfm/config/${i}" "${ED}usr/share/texmf/fonts/map/dvipdfm/base" || die "moving .map file failed"
  37         done
  38
  39         dodir /usr/share/texmf/fonts/enc/dvipdfm
  40
  41         mv "${ED}usr/share/texmf/dvipdfm/base" "${ED}usr/share/texmf/fonts/enc/dvipdfm/base" || die "moving .enc file failed"
  42
  43         dodoc AUTHORS ChangeLog Credits NEWS OBTAINING README* TODO
  44
  45         docinto doc
  46         dodoc doc/*
  47
  48         docinto latex-support
  49         dodoc latex-support/*
  50
  51         insinto /usr/share/texmf/tex/latex/dvipdfm/
  52         doins latex-support/dvipdfm.def
  53 }
  54
  55 pkg_postinst() {
  56         if [ "$ROOT" = "/" ] ; then
  57                 "${EPREFIX}"/usr/sbin/texmf-update
  58         fi
  59 }