app-text/docbook-xml-dtd/docbook-xml-dtd-4.1.2-r6.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 inherit sgml-catalog
   6
   7 MY_P="docbkx412"
   8 DESCRIPTION="Docbook DTD for XML"
   9 HOMEPAGE="http://www.docbook.org/"
  10 SRC_URI="http://www.docbook.org/xml/${PV}/${MY_P}.zip"
  11
  12 LICENSE="docbook"
  13 SLOT="${PV}"
  14 KEYWORDS="alpha amd64 arm arm64 hppa ia64 m68k ~mips ppc ppc64 s390 sh sparc x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~x86-interix ~amd64-linux ~arm-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~x64-solaris ~x86-solaris"
  15 IUSE=""
  16
  17 RDEPEND=">=app-text/docbook-xsl-stylesheets-1.65
  18         >=app-text/build-docbook-catalog-1.2"
  19 DEPEND=">=app-arch/unzip-5.41"
  20
  21 sgml-catalog_cat_include "/etc/sgml/xml-docbook-${PV}.cat" \
  22         "/etc/sgml/sgml-docbook.cat"
  23 sgml-catalog_cat_include "/etc/sgml/xml-docbook-${PV}.cat" \
  24         "/usr/share/sgml/docbook/xml-dtd-${PV}/docbook.cat"
  25
  26 S=${WORKDIR}
  27
  28 src_unpack() {
  29         unpack ${A}
  30
  31         # Prepend OVERRIDE directive
  32         sed -i -e '1i\\OVERRIDE YES' docbook.cat
  33 }
  34
  35 src_install() {
  36         keepdir /etc/xml
  37
  38         insinto /usr/share/sgml/docbook/xml-dtd-${PV}
  39         doins *.cat *.dtd *.mod || die
  40         insinto /usr/share/sgml/docbook/xml-dtd-${PV}/ent
  41         doins ent/*.ent || die
  42
  43         dodoc ChangeLog *.txt
  44 }
  45
  46 pkg_postinst() {
  47         build-docbook-catalog
  48         sgml-catalog_pkg_postinst
  49 }
  50
  51 pkg_postrm() {
  52         build-docbook-catalog
  53         sgml-catalog_pkg_postrm
  54 }