app-text/build-docbook-catalog/build-docbook-catalog-1.20.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 DESCRIPTION="DocBook XML catalog auto-updater"
   8 HOMEPAGE="http://sources.gentoo.org/gentoo-src/build-docbook-catalog/"
   9 SRC_URI="mirror://gentoo/${P}.tar.xz
  10         https://dev.gentoo.org/~floppym/distfiles/${P}.tar.xz
  11         https://dev.gentoo.org/~vapier/dist/${P}.tar.xz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~alpha ~amd64 ~arm arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~ppc-aix ~amd64-fbsd ~sparc-fbsd ~x86-fbsd ~x64-freebsd ~x86-freebsd ~ia64-hpux ~x86-interix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~m68k-mint ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16 IUSE=""
  17
  18 RDEPEND="|| ( sys-apps/util-linux app-misc/getopt )
  19         !<app-text/docbook-xsl-stylesheets-1.73.1
  20         dev-libs/libxml2"
  21 DEPEND=""
  22
  23 pkg_setup() {
  24         # export for bug #490754
  25         export MAKEOPTS+=" EPREFIX=${EPREFIX}"
  26 }
  27
  28 src_prepare() {
  29         sed -i -e "/^EPREFIX=/s:=.*:='${EPREFIX}':" build-docbook-catalog || die
  30         has_version sys-apps/util-linux || sed -i -e '/^GETOPT=/s/getopt/&-long/' build-docbook-catalog || die
  31 }
  32
  33 pkg_postinst() {
  34         # New version -> regen files
  35         build-docbook-catalog
  36 }