app-text/atril/atril-1.12.2-r4.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MATE_LA_PUNT="yes"
   7
   8 inherit mate
   9
  10 if [[ ${PV} != 9999 ]]; then
  11         KEYWORDS="amd64 ~arm x86"
  12 fi
  13
  14 DESCRIPTION="Atril document viewer for MATE"
  15 LICENSE="GPL-2"
  16 SLOT="0"
  17
  18 IUSE="caja dbus debug djvu dvi epub +introspection gnome-keyring gtk3 +postscript t1lib tiff xps"
  19
  20 REQUIRED_USE="t1lib? ( dvi )
  21         !gtk3? ( !epub )" #608604
  22
  23 RDEPEND=">=app-text/poppler-0.16:0=[cairo]
  24         app-text/rarian:0
  25         dev-libs/atk:0
  26         >=dev-libs/glib-2.36:2
  27         >=dev-libs/libxml2-2.5:2
  28         >=mate-base/mate-desktop-1.9[gtk3(-)=]
  29         sys-libs/zlib:0
  30         x11-libs/gdk-pixbuf:2
  31         x11-libs/libICE:0
  32         >=x11-libs/libSM-1:0
  33         x11-libs/libX11:0
  34         >=x11-libs/cairo-1.9.10:0
  35         x11-libs/pango:0
  36         caja? ( >=mate-base/caja-1.8[gtk3(-)=,introspection?] )
  37         djvu? ( >=app-text/djvu-3.5.17:0 )
  38         dvi? (
  39                 virtual/tex-base:0
  40                 t1lib? ( >=media-libs/t1lib-5:5 )
  41         )
  42         epub? ( dev-libs/mathjax )
  43         gnome-keyring? ( >=app-crypt/libsecret-0.5:0 )
  44         !gtk3? (
  45                 >=x11-libs/gtk+-2.24.0:2[introspection?]
  46         )
  47         gtk3? (
  48                 >=x11-libs/gtk+-3.0:3[introspection?]
  49                 epub? ( >=net-libs/webkit-gtk-2.4.3:4 )
  50         )
  51         introspection? ( >=dev-libs/gobject-introspection-0.6:= )
  52         postscript? ( >=app-text/libspectre-0.2:0 )
  53         tiff? ( >=media-libs/tiff-3.6:0 )
  54         xps? ( >=app-text/libgxps-0.2.0:0 )
  55         !!app-text/mate-document-viewer"
  56
  57 DEPEND="${RDEPEND}
  58         app-text/docbook-xml-dtd:4.1.2
  59         app-text/yelp-tools:0
  60         >=app-text/scrollkeeper-dtd-1:1.0
  61         dev-util/gtk-doc
  62         dev-util/gtk-doc-am
  63         >=dev-util/intltool-0.50.1:*
  64         virtual/pkgconfig:*
  65         sys-devel/gettext:*"
  66
  67 # Tests use dogtail which is not available on Gentoo.
  68 RESTRICT="test"
  69
  70 src_configure() {
  71         # Passing --disable-help would drop offline help, that would be inconsistent
  72         # with helps of the most of GNOME apps that doesn't require network for that.
  73         mate_src_configure \
  74                 --disable-tests \
  75                 --enable-comics \
  76                 --enable-pdf \
  77                 --enable-pixbuf \
  78                 --enable-previewer \
  79                 --enable-thumbnailer \
  80                 --with-matedesktop \
  81                 --with-gtk=$(usex gtk3 3.0 2.0) \
  82                 $(use_with gnome-keyring keyring) \
  83                 $(use_enable caja) \
  84                 $(use_enable dbus) \
  85                 $(use_enable debug) \
  86                 $(use_enable djvu) \
  87                 $(use_enable dvi) \
  88                 $(use_enable epub) \
  89                 $(use_enable introspection) \
  90                 $(use_enable postscript ps) \
  91                 $(use_enable t1lib) \
  92                 $(use_enable tiff) \
  93                 $(use_enable xps)
  94 }