app-shells/ksh/ksh-2020.0.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit meson
   7
   8 if [[ ${PV} == 9999 ]]; then
   9         inherit git-r3
  10         EGIT_REPO_URI="https://github.com/att/ast"
  11 else
  12         KEYWORDS="~alpha ~amd64 ~arm ~ia64 ~ppc ~ppc64 ~s390 ~sparc ~x86"
  13         MY_PV="${PV/_/-}"
  14         MY_P="${PN}-${MY_PV}"
  15         SRC_URI="https://github.com/att/ast/releases/download/${MY_PV}/${MY_P}.tar.gz"
  16         S="${WORKDIR}/${MY_P}"
  17 fi
  18
  19 DESCRIPTION="The Original Korn Shell, 1993 revision (ksh93)"
  20 HOMEPAGE="https://github.com/att/ast"
  21
  22 LICENSE="CPL-1.0 EPL-1.0"
  23 SLOT="0"
  24
  25 RDEPEND="!app-shells/pdksh"
  26
  27 PATCHES=(
  28         "${FILESDIR}"/ksh-2020.0.0-ensure-user-set.patch
  29         "${FILESDIR}"/ksh-2020.0.0-skip-api-test.patch
  30         "${FILESDIR}"/CVE-2019-14868.patch
  31 )
  32
  33 src_test() {
  34         # https://bugs.gentoo.org/702570
  35         addwrite /proc/self
  36         local cmd=(
  37                 meson test
  38                 -C "${BUILD_DIR}"
  39                 --num-processes "$(makeopts_jobs ${NINJAOPTS:-${MAKEOPTS}})"
  40         )
  41         echo "${cmd[@]}" >&2
  42         # https://github.com/att/ast/issues/1392
  43         env -u T "${cmd[@]}" || die
  44 }
  45
  46 src_install() {
  47         meson_src_install
  48         dodir /bin
  49         mv "${ED}/usr/bin/ksh" "${ED}/bin/ksh" || die
  50 }