app-shells/fish/fish-3.0.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit cmake readme.gentoo-r1
   7
   8 DESCRIPTION="Friendly Interactive SHell"
   9 HOMEPAGE="http://fishshell.com/"
  10
  11 MY_PV="${PV/_beta/b}"
  12 MY_P="${PN}-${MY_PV}"
  13
  14 if [[ ${PV} == "9999" ]]; then
  15         inherit git-r3
  16         EGIT_REPO_URI="https://github.com/${PN}-shell/${PN}-shell.git"
  17 else
  18         SRC_URI="https://github.com/${PN}-shell/${PN}-shell/releases/download/${MY_PV}/${MY_P}.tar.gz"
  19         KEYWORDS="~alpha amd64 arm arm64 ~hppa ppc ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x86-solaris"
  20 fi
  21
  22 LICENSE="GPL-2"
  23 SLOT="0"
  24
  25 IUSE="doc nls test"
  26 RESTRICT="!test? ( test )"
  27
  28 RDEPEND="
  29         >=dev-libs/libpcre2-10.21[pcre32]
  30         sys-devel/bc
  31         sys-libs/ncurses:0=[unicode]
  32 "
  33
  34 DEPEND="${RDEPEND}
  35         doc? ( app-doc/doxygen )
  36         nls? ( sys-devel/gettext )
  37         test? ( dev-tcltk/expect )
  38 "
  39
  40 PATCHES=( "${FILESDIR}/fix-histfile-test-on-ppc.patch" )
  41
  42 S="${WORKDIR}/${MY_P}"
  43
  44 src_prepare() {
  45         # workaround for https://github.com/fish-shell/fish-shell/issues/4883
  46         sed -i 's#${TEST_INSTALL_DIR}/${CMAKE_INSTALL_PREFIX}#${TEST_INSTALL_DIR}#' \
  47                 cmake/Tests.cmake || die
  48         cmake_src_prepare
  49 }
  50
  51 src_configure() {
  52         local mycmakeargs=(
  53                 -DCMAKE_INSTALL_BINDIR="${EPREFIX}/bin"
  54                 -DCMAKE_INSTALL_SYSCONFDIR="${EPREFIX}/etc"
  55                 -DCURSES_NEED_NCURSES=ON
  56                 -DINTERNAL_WCWIDTH=OFF
  57                 -DBUILD_DOCS="$(usex doc)"
  58                 -DWITH_GETTEXT="$(usex nls)"
  59         )
  60         cmake_src_configure
  61 }
  62
  63 src_install() {
  64         cmake_src_install
  65         keepdir /usr/share/fish/vendor_{completions,conf,functions}.d
  66         readme.gentoo_create_doc
  67 }
  68
  69 src_test() {
  70         cmake_build -j1 test
  71 }
  72
  73 pkg_postinst() {
  74         readme.gentoo_print_elog
  75 }