app-portage/elogv/elogv-0.7.8-r3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 PYTHON_REQ_USE="ncurses"
   8 DISTUTILS_USE_SETUPTOOLS=no
   9
  10 inherit distutils-r1
  11
  12 DESCRIPTION="Curses based utility to parse the contents of elogs created by Portage"
  13 HOMEPAGE="https://github.com/gentoo/elogv"
  14 SRC_URI="https://github.com/gentoo/${PN}/archive/${PV}.tar.gz -> ${P}.tar.gz"
  15
  16 LICENSE="GPL-2"
  17 SLOT="0"
  18 KEYWORDS="~alpha amd64 ~arm ppc ~ppc64 sparc x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  19
  20 RDEPEND="sys-apps/portage[${PYTHON_USEDEP}]"
  21 DEPEND="${RDEPEND}"
  22
  23 DOCS=( README )
  24
  25 src_install() {
  26         distutils-r1_src_install
  27
  28         # unset LINGUAS => install all languages
  29         # empty LINGUAS => install none
  30         local i
  31         if [[ -n "${LINGUAS+x}" ]] ; then
  32                 for i in $(ls "${ED}"/usr/share/locale/) ; do
  33                         if ! has ${i} ${LINGUAS} ; then
  34                                 rm -rf "${ED}"/usr/share/{locale,man}/${i}
  35                         fi
  36                 done
  37         fi
  38 }
  39
  40 pkg_postinst() {
  41         elog "Optional dependencies:"
  42         elog "  dev-python/pyliblzma (for xz compressed elog files)"
  43         elog
  44         elog "In order to use this software, you need to activate"
  45         elog "Portage's elog features.  Required is"
  46         elog "           PORTAGE_ELOG_SYSTEM=\"save\" "
  47         elog "and at least one out of "
  48         elog "           PORTAGE_ELOG_CLASSES=\"warn error info log qa\""
  49         elog "More information on the elog system can be found"
  50         elog "in ${EPREFIX}/usr/share/portage/config/make.conf.example"
  51         elog
  52         elog "To operate properly this software needs the directory"
  53         elog "${PORT_LOGDIR:-${EPREFIX}/var/log/portage}/elog created, belonging to group portage."
  54         elog "To start the software as a user, add yourself to the portage"
  55         elog "group."
  56         elog
  57 }