app-pda/barry/barry-0.18.3.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit bash-completion-r1 eutils gnome2-utils udev
   7
   8 DESCRIPTION="Sync, backup, program management, and charging for BlackBerry devices"
   9 HOMEPAGE="http://www.netdirect.ca/software/packages/barry/"
  10 SRC_URI="mirror://sourceforge/barry/${P}.tar.bz2"
  11
  12 LICENSE="CC-BY-SA-3.0 GPL-2" #See logo/README for CCPL
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~x86"
  15 IUSE="boost desktop doc gui nls static-libs"
  16
  17 RDEPEND=">=dev-cpp/libxmlpp-2.6
  18         >=dev-libs/glib-2
  19         >=dev-libs/libtar-1.2.11-r2
  20         >=media-libs/libsdl-1.2
  21         >=sys-fs/fuse-2.5
  22         sys-libs/zlib
  23         virtual/libusb:1
  24         boost? ( >=dev-libs/boost-1.33 )
  25         desktop? ( >=net-libs/libgcal-0.9.6 )
  26         gui? (
  27                 dev-cpp/glibmm:2
  28                 dev-cpp/gtkmm:2.4
  29                 dev-cpp/libglademm:2.4
  30                 )"
  31 DEPEND="${RDEPEND}
  32         virtual/pkgconfig
  33         doc? ( >=app-doc/doxygen-1.5.6 )
  34         nls? ( >=sys-devel/gettext-0.18.1.1 )"
  35
  36 DOCS=( AUTHORS ChangeLog KnownBugs NEWS README TODO )
  37
  38 src_prepare() {
  39         sed -i -e 's:plugdev:usb:g' "${S}"/udev/99-blackberry-perms.rules || die
  40         sed -i -e '/Icon/s:=.*:=barry:' "${S}"/menu/*.desktop || die
  41 }
  42
  43 src_configure() {
  44         econf \
  45                 $(use_enable nls) \
  46                 $(use_enable static-libs static) \
  47                 $(use_enable boost) \
  48                 $(use_enable gui) \
  49                 $(use_enable desktop) \
  50                 --disable-rpath
  51 }
  52
  53 src_compile() {
  54         default
  55
  56         if use doc; then
  57                 cd "${S}"
  58                 doxygen || die
  59         fi
  60 }
  61
  62 src_install() {
  63         default
  64
  65         # docs
  66         rm -rf "${S}"/doc/www/*.{php,sh}
  67         find "${S}"/doc/www/doxygen/html -name "*.map" -size 0 -exec rm -f {} +
  68         use doc && dohtml "${S}"/doc/www/doxygen/html/*
  69         rm -rf "${S}"/doc/www
  70         dodoc -r "${S}"/doc/*
  71
  72         # Skipping different (old Fedora) rules 69-blackberry.rules in purpose
  73         udev_dorules "${S}"/udev/10-blackberry.rules "${S}"/udev/99-blackberry-perms.rules
  74
  75         # blacklist for BERRY_CHARGE kernel module
  76         insinto /lib/modprobe.d
  77         doins "${S}"/modprobe/blacklist-berry_charge.conf
  78
  79         # pppd options files
  80         docinto ppp
  81         dodoc "${S}"/ppp/*
  82
  83         dobashcomp "${S}"/bash/btool "${S}"/bash/bjavaloader
  84
  85         newicon -s scalable "${S}"/logo/${PN}_logo_icon.svg ${PN}.svg
  86         use desktop && domenu "${S}"/menu/barrydesktop.desktop
  87         use gui && domenu "${S}"/menu/barrybackup.desktop
  88
  89         prune_libtool_files
  90 }
  91
  92 pkg_preinst() {
  93         gnome2_icon_savelist
  94 }
  95
  96 pkg_postinst() {
  97         gnome2_icon_cache_update
  98
  99         elog "Barry requires you to be a member of the \"usb\" group."
 100         ewarn
 101         ewarn "Barry and the in-kernel module 'BERRY_CHARGE' are incompatible."
 102         ewarn
 103         ewarn "Kernel-based USB suspending can discharge your blackberry."
 104         ewarn "Use at least kernel 2.6.22 and/or disable CONFIG_USB_SUSPEND."
 105         ewarn
 106 }
 107
 108 pkg_postrm() {
 109         gnome2_icon_cache_update
 110 }