app-pda/barry/barry-0.18.3.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit bash-completion-r1 eutils flag-o-matic gnome2-utils ltprune udev
   6
   7 DESCRIPTION="Sync, backup, program management, and charging for BlackBerry devices"
   8 HOMEPAGE="http://www.netdirect.ca/software/packages/barry/"
   9 SRC_URI="mirror://sourceforge/barry/${P}.tar.bz2"
  10
  11 LICENSE="CC-BY-SA-3.0 GPL-2" #See logo/README for CCPL
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="boost doc gui nls static-libs"
  15
  16 RDEPEND=">=dev-cpp/libxmlpp-2.6:2.6
  17         dev-libs/glib:2
  18         >=dev-libs/libtar-1.2.11-r2
  19         >=media-libs/libsdl-1.2
  20         >=sys-fs/fuse-2.5:=
  21         sys-libs/zlib
  22         virtual/libusb:1
  23         boost? ( >=dev-libs/boost-1.33 )
  24         gui? (
  25                 dev-cpp/glibmm:2
  26                 dev-cpp/gtkmm:2.4
  27                 dev-cpp/libglademm:2.4
  28                 )"
  29 DEPEND="${RDEPEND}
  30         virtual/pkgconfig
  31         doc? ( >=app-doc/doxygen-1.5.6 )
  32         nls? ( >=sys-devel/gettext-0.18.1.1 )"
  33
  34 DOCS=( AUTHORS ChangeLog KnownBugs NEWS README TODO )
  35
  36 src_prepare() {
  37         epatch "${FILESDIR}"/${PN}-0.18.4-shared_ptr.patch
  38
  39         append-cxxflags -std=c++11
  40
  41         sed -i -e 's:plugdev:usb:g' "${S}"/udev/99-blackberry-perms.rules || die
  42         sed -i -e '/Icon/s:=.*:=barry:' "${S}"/menu/*.desktop || die
  43 }
  44
  45 src_configure() {
  46         econf \
  47                 $(use_enable nls) \
  48                 $(use_enable static-libs static) \
  49                 $(use_enable boost) \
  50                 $(use_enable gui) \
  51                 --disable-desktop \
  52                 --disable-rpath
  53 }
  54
  55 src_compile() {
  56         default
  57
  58         if use doc; then
  59                 cd "${S}"
  60                 doxygen || die
  61         fi
  62 }
  63
  64 src_install() {
  65         default
  66
  67         # docs
  68         rm -rf "${S}"/doc/www/*.{php,sh}
  69         find "${S}"/doc/www/doxygen/html -name "*.map" -size 0 -exec rm -f {} +
  70         use doc && dohtml "${S}"/doc/www/doxygen/html/*
  71         rm -rf "${S}"/doc/www
  72         dodoc -r "${S}"/doc/*
  73
  74         # Skipping different (old Fedora) rules 69-blackberry.rules in purpose
  75         udev_dorules "${S}"/udev/10-blackberry.rules "${S}"/udev/99-blackberry-perms.rules
  76
  77         # blacklist for BERRY_CHARGE kernel module
  78         insinto /lib/modprobe.d
  79         doins "${S}"/modprobe/blacklist-berry_charge.conf
  80
  81         # pppd options files
  82         docinto ppp
  83         dodoc "${S}"/ppp/*
  84
  85         dobashcomp "${S}"/bash/btool "${S}"/bash/bjavaloader
  86
  87         newicon -s scalable "${S}"/logo/${PN}_logo_icon.svg ${PN}.svg
  88         use gui && domenu "${S}"/menu/barrybackup.desktop
  89
  90         prune_libtool_files
  91 }
  92
  93 pkg_preinst() {
  94         gnome2_icon_savelist
  95 }
  96
  97 pkg_postinst() {
  98         gnome2_icon_cache_update
  99 }
 100
 101 pkg_postrm() {
 102         gnome2_icon_cache_update
 103 }