app-office/texmacs/texmacs-1.99.5.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit autotools fdo-mime gnome2-utils
   8
   9 MY_P=${P/tex/TeX}-src
  10
  11 DESCRIPTION="Wysiwyg text processor with high-quality maths"
  12 HOMEPAGE="http://www.texmacs.org/"
  13 SRC_URI="ftp://ftp.texmacs.org/pub/TeXmacs/tmftp/source/${MY_P}.tar.gz"
  14
  15 LICENSE="GPL-3"
  16 SLOT="0"
  17 IUSE="imlib jpeg netpbm pdf svg spell"
  18 KEYWORDS="~alpha ~amd64 ~ppc ~x86 ~x86-interix ~amd64-linux ~x86-linux"
  19
  20 RDEPEND="
  21         app-text/ghostscript-gpl
  22         dev-scheme/guile:12[deprecated]
  23         media-libs/freetype
  24         x11-apps/xmodmap
  25         x11-libs/libXext
  26         virtual/latex-base
  27         dev-qt/qtgui:4
  28         imlib? ( media-libs/imlib2 )
  29         jpeg? ( || ( media-gfx/imagemagick media-gfx/jpeg2ps ) )
  30         netpbm? ( media-libs/netpbm )
  31         spell? ( app-text/aspell )
  32         svg? ( || ( media-gfx/inkscape gnome-base/librsvg:2 ) )
  33 "
  34 DEPEND="${RDEPEND}
  35         x11-proto/xproto"
  36
  37 S="${WORKDIR}/${MY_P}"
  38
  39 PATCHES=(
  40         # respect LDFLAGS, bug #338459
  41         "${FILESDIR}"/${PN}-plugins-1.patch
  42
  43         # dont update mime and desktop databases and icon cache
  44         "${FILESDIR}"/${PN}-updates.patch
  45
  46         "${FILESDIR}"/${PN}-1.99.2-desktop.patch
  47
  48         # remove new/delete declarations, bug 590002
  49         "${FILESDIR}"/${PN}-1.99-remove-new-declaration.patch
  50 )
  51
  52 src_prepare() {
  53         default
  54
  55         mv configure.{in,ac} || die
  56
  57         eautoreconf
  58
  59         # delete files that contain binary
  60         # headers only used on OS X
  61         rm src/{Plugins/Ghostscript/._ghostscript.cpp,System/Misc/._sys_utils.cpp} || die
  62 }
  63
  64 src_configure() {
  65         econf \
  66                 --enable-optimize="${CXXFLAGS}" \
  67                 $(use_with imlib imlib2) \
  68                 $(use_enable pdf pdf-renderer)
  69 }
  70
  71 pkg_postinst() {
  72         fdo-mime_desktop_database_update
  73         fdo-mime_mime_database_update
  74         gnome2_icon_cache_update
  75 }
  76
  77 pkg_postrm() {
  78         fdo-mime_desktop_database_update
  79         fdo-mime_mime_database_update
  80         gnome2_icon_cache_update
  81 }