app-office/planner/planner-0.14.6_p20130520.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="5"
   6 GCONF_DEBUG="no"
   7 GNOME2_LA_PUNT="yes"
   8 PYTHON_COMPAT=( python2_7 )
   9
  10 inherit gnome2 python-single-r1
  11
  12 DESCRIPTION="Project manager for Gnome"
  13 HOMEPAGE="http://live.gnome.org/Planner/"
  14 SRC_URI="https://dev.gentoo.org/~eva/distfiles/${PN}/${P}.tar.xz"
  15
  16 SLOT="0"
  17 LICENSE="GPL-2"
  18 KEYWORDS="~alpha amd64 ~ppc ~sparc x86"
  19 IUSE="eds examples python"
  20 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  21
  22 RDEPEND="
  23         >=dev-libs/glib-2.6:2
  24         >=x11-libs/gtk+-2.14:2
  25         >=gnome-base/libgnomecanvas-2.10
  26         >=gnome-base/libgnomeui-2.10
  27         >=gnome-base/libglade-2.4:2.0
  28         >=gnome-base/gconf-2.6:2
  29         >=dev-libs/libxml2-2.6.27:2
  30         >=dev-libs/libxslt-1.1.23
  31         python? (
  32                 ${PYTHON_DEPS}
  33                 >=dev-python/pygtk-2.6:2[${PYTHON_USEDEP}] )
  34         eds? (
  35                 >=gnome-extra/evolution-data-server-3.6:=
  36                 >=mail-client/evolution-3.6 )"
  37
  38 DEPEND="${RDEPEND}
  39         app-text/scrollkeeper
  40         dev-util/gtk-doc-am
  41         >=dev-util/intltool-0.35.5
  42         gnome-base/gnome-common
  43         virtual/pkgconfig
  44 "
  45
  46 S="${WORKDIR}/${PN}-0.14.6"
  47
  48 src_configure() {
  49         # FIXME: disable eds backend for now, it fails, upstream bug #654005
  50         # We need to set compile-warnings to a different value as it doesn't use
  51         # standard macro: https://bugzilla.gnome.org/703067
  52         gnome2_src_configure \
  53                 $(use_enable python) \
  54                 $(use_enable python python-plugin) \
  55                 $(use_enable eds) \
  56                 --disable-eds-backend \
  57                 --with-database=no \
  58                 --disable-update-mimedb \
  59                 --enable-compile-warnings=yes
  60                 #$(use_enable eds eds-backend)
  61 }
  62
  63 src_install() {
  64         # error: relink `libstorage-mrproject-1.la' with the above command before installing it
  65         # Try to drop workaround on next snapshot or bump
  66         MAKEOPTS="${MAKEOPTS} -j1" gnome2_src_install \
  67                 sqldocdir="\$(datadir)/doc/${PF}" \
  68                 sampledir="\$(datadir)/doc/${PF}/examples"
  69
  70         if ! use examples; then
  71                 rm -rf "${D}/usr/share/doc/${PF}/examples"
  72         fi
  73 }