app-office/orage/orage-4.12.1-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2-utils
   7
   8 DESCRIPTION="A time managing application (and panel plug-in) for the Xfce desktop environment"
   9 HOMEPAGE="https://git.xfce.org/apps/orage/"
  10 SRC_URI="https://archive.xfce.org/src/apps/${PN}/${PV%.*}/${P}.tar.bz2"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~alpha amd64 arm ~hppa ~ia64 ppc ppc64 ~sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
  15 IUSE="berkdb +clock-panel-plugin dbus libnotify"
  16
  17 RDEPEND=">=dev-libs/libical-0.48:=
  18         dev-libs/popt:=
  19         >=x11-libs/gtk+-2.10:2=
  20         berkdb? ( >=sys-libs/db-4:= )
  21         clock-panel-plugin? ( >=xfce-base/xfce4-panel-4.10:= )
  22         dbus? ( >=dev-libs/dbus-glib-0.100:= )
  23         libnotify? ( >=x11-libs/libnotify-0.7:= )"
  24 DEPEND="${RDEPEND}
  25         dev-util/intltool
  26         sys-devel/gettext
  27         >=sys-devel/libtool-2.2.6
  28         virtual/pkgconfig"
  29
  30 PATCHES=(
  31         "${FILESDIR}"/0001-fix-build-with-libical-version-3.patch
  32 )
  33
  34 src_configure() {
  35         local myconf=(
  36                 --libexecdir="${EPREFIX}/usr/$(get_libdir)"
  37                 --docdir="${EPREFIX}"/usr/share/doc/${PF}/html
  38                 $(use_enable clock-panel-plugin libxfce4panel)
  39                 $(use_enable dbus)
  40                 $(use_enable libnotify)
  41                 $(use_with berkdb bdb4)
  42         )
  43
  44         econf "${myconf[@]}"
  45 }
  46
  47 src_install() {
  48         default
  49         find "${D}" -name '*.la' -delete || die
  50 }
  51
  52 pkg_preinst() {
  53         # Replacing directory by symlink is unreliable
  54         if [[ -L ${EROOT}/usr/share/orage/doc/C ]]; then
  55                 rm -f "${EROOT}/usr/share/orage/doc/C" || die
  56         fi
  57 }
  58
  59 pkg_postinst() {
  60         gnome2_icon_cache_update
  61         xdg_desktop_database_update
  62 }
  63
  64 pkg_postrm() {
  65         gnome2_icon_cache_update
  66         xdg_desktop_database_update
  67 }