app-office/moneyguru/moneyguru-3.0.1-r2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7} )
   7
   8 inherit python-single-r1
   9
  10 DESCRIPTION="Future-aware personal finances management"
  11 HOMEPAGE="https://hardcoded.net/moneyguru"
  12 SRC_URI="https://download.hardcoded.net/${P}.tar.gz"
  13
  14 LICENSE="GPL-3+"
  15 SLOT="0"
  16 KEYWORDS="amd64"
  17 IUSE="test"
  18 RESTRICT="!test? ( test )"
  19 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  20
  21 RDEPEND="${PYTHON_DEPS}
  22         dev-db/sqlite:3
  23         dev-libs/glib:2
  24         $(python_gen_cond_dep '
  25                 dev-python/PyQt5[${PYTHON_MULTI_USEDEP},gui,widgets,printsupport]
  26         ')
  27         dev-qt/qttranslations"
  28 DEPEND="${RDEPEND}
  29         test? (
  30                 $(python_gen_cond_dep '
  31                         dev-python/pytest[${PYTHON_MULTI_USEDEP}]
  32                 ')
  33                 dev-util/cunit
  34         )"
  35
  36 _emake() {
  37         emake CFLAGS="\$(DEFAULT_CFLAGS) ${CFLAGS}" \
  38                 SHEBANG="${PYTHON}" \
  39                 DESTDIR="${ED}" \
  40                 PREFIX="${EPREFIX}/usr" \
  41                 "$@"
  42 }
  43
  44 src_compile() {
  45         _emake
  46 }
  47
  48 src_install() {
  49         _emake install
  50 }
  51
  52 src_test() {
  53         emake -C ccore CFLAGS="\$(DEFAULT_CFLAGS) ${CFLAGS}" tests
  54         pytest -vv core || die "Tests failed with ${EPYTHON}"
  55 }