app-office/libreoffice-l10n/libreoffice-l10n-5.4.2.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit rpm eutils multilib versionator
   7
   8 MY_PV=$(get_version_component_range 1-3)
   9
  10 DESCRIPTION="Translations for the Libreoffice suite"
  11 HOMEPAGE="http://www.libreoffice.org"
  12 BASE_SRC_URI_TESTING="http://download.documentfoundation.org/${PN/-l10n/}/testing/${MY_PV}/rpm"
  13 BASE_SRC_URI_STABLE="http://download.documentfoundation.org/${PN/-l10n/}/stable/${MY_PV}/rpm"
  14
  15 LICENSE="|| ( LGPL-3 MPL-1.1 )"
  16 SLOT="0"
  17 KEYWORDS="amd64 ~arm ~arm64 x86 ~amd64-linux ~x86-linux"
  18 IUSE="offlinehelp"
  19
  20 #
  21 # when changing the language lists, please be careful to preserve the spaces (bug 491728)
  22 #
  23 # "en:en-US" for mapping from Gentoo "en" to upstream "en-US" etc.
  24 LANGUAGES_HELP=" am ast bg bn-IN bn bo bs ca-valencia ca cs da de dz el en-GB en:en-US en-ZA eo es et eu fi fr gl gu he hi hr hu id is it ja ka km ko mk nb ne nl nn om pl pt-BR pt ru si sk sl sq sv tg tr ug uk vi zh-CN zh-TW "
  25 LANGUAGES="${LANGUAGES_HELP}af ar as be br brx cy dgo fa ga gd gug kk kmr-Latn kn kok ks lb lo lt lv mai ml mn mni mr my nr nso oc or pa:pa-IN ro rw sa:sa-IN sat sd sid sr-Latn sr ss st sw-TZ ta te th tn ts tt uz ve xh zu "
  26
  27 for lang in ${LANGUAGES_HELP}; do
  28         helppack="offlinehelp? ( ${BASE_SRC_URI_STABLE}/x86/LibreOffice_${MY_PV}_Linux_x86_rpm_helppack_${lang#*:}.tar.gz -> LibreOffice_${PV}_Linux_x86_rpm_helppack_${lang#*:}.tar.gz ${BASE_SRC_URI_TESTING}/x86/LibreOffice_${PV}_Linux_x86_rpm_helppack_${lang#*:}.tar.gz )"
  29         SRC_URI+=" l10n_${lang%:*}? ( ${helppack} )"
  30 done
  31 for lang in ${LANGUAGES}; do
  32         if [[ ${lang%:*} != en ]]; then
  33                 langpack="${BASE_SRC_URI_STABLE}/x86/LibreOffice_${MY_PV}_Linux_x86_rpm_langpack_${lang#*:}.tar.gz -> LibreOffice_${PV}_Linux_x86_rpm_langpack_${lang#*:}.tar.gz ${BASE_SRC_URI_TESTING}/x86/LibreOffice_${PV}_Linux_x86_rpm_langpack_${lang#*:}.tar.gz"
  34                 SRC_URI+=" l10n_${lang%:*}? ( ${langpack} )"
  35         fi
  36         IUSE+=" l10n_${lang%:*}"
  37 done
  38 unset lang helppack langpack
  39
  40 RDEPEND+="app-text/hunspell"
  41
  42 RESTRICT="strip"
  43
  44 S="${WORKDIR}"
  45
  46 src_prepare() {
  47         default
  48
  49         local lang dir rpmdir
  50
  51         # First remove dictionaries, we want to use system ones.
  52         find "${S}" -name *dict*.rpm -delete || die "Failed to remove dictionaries"
  53
  54         for lang in ${LANGUAGES}; do
  55                 # break away if not enabled
  56                 use l10n_${lang%:*} || continue
  57
  58                 dir=${lang#*:}
  59
  60                 # for english we provide just helppack, as translation is always there
  61                 if [[ ${lang%:*} != en ]]; then
  62                         rpmdir="LibreOffice_${PV}_Linux_x86_rpm_langpack_${dir}/RPMS/"
  63                         [[ -d ${rpmdir} ]] || die "Missing directory: ${rpmdir}"
  64                         rpm_unpack ./${rpmdir}/*.rpm
  65                 fi
  66                 if [[ "${LANGUAGES_HELP}" =~ " ${lang} " ]] && use offlinehelp; then
  67                         rpmdir="LibreOffice_${PV}_Linux_x86_rpm_helppack_${dir}/RPMS/"
  68                         [[ -d ${rpmdir} ]] || die "Missing directory: ${rpmdir}"
  69                         rpm_unpack ./${rpmdir}/*.rpm
  70                 fi
  71         done
  72 }
  73
  74 src_configure() { :; }
  75 src_compile() { :; }
  76
  77 src_install() {
  78         local dir="${S}"/opt/${PN/-l10n/}$(get_version_component_range 1-2)/
  79         # Condition required for people that do not install anything eg no l10n
  80         # or just english with no offlinehelp.
  81         if [[ -d "${dir}" ]] ; then
  82                 insinto /usr/$(get_libdir)/${PN/-l10n/}/
  83                 doins -r "${dir}"/*
  84         fi
  85         # remove extensions that are in the l10n for some weird reason
  86         rm -rf "${ED}"usr/$(get_libdir)/${PN/-l10n/}/share/extensions/ || \
  87                 die "Failed to remove extensions"
  88 }