app-office/gtg/gtg-0.3.1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 PYTHON_COMPAT=( python2_7 )
   6
   7 inherit eutils fdo-mime gnome2-utils distutils-r1 versionator
   8
   9 MY_PV="$(get_version_component_range 1-2)"
  10 DESCRIPTION="Personal organizer for the GNOME desktop environment"
  11 HOMEPAGE="http://gtgnome.net/"
  12 SRC_URI="https://launchpad.net/${PN}/${MY_PV}/${PV}/+download/${P}.tar.gz"
  13
  14 LICENSE="GPL-3"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE=""
  18
  19 RDEPEND="
  20         dev-python/configobj[${PYTHON_USEDEP}]
  21         dev-python/dbus-python[${PYTHON_USEDEP}]
  22         dev-python/liblarch[${PYTHON_USEDEP}]
  23         dev-python/notify-python[${PYTHON_USEDEP}]
  24         dev-python/pycairo[${PYTHON_USEDEP}]
  25         dev-python/pygobject:2[${PYTHON_USEDEP}]
  26         dev-python/pygtk[${PYTHON_USEDEP}]
  27         dev-python/python-dateutil[${PYTHON_USEDEP}]
  28         dev-python/pyxdg[${PYTHON_USEDEP}]
  29         dev-python/simplejson[${PYTHON_USEDEP}]
  30 "
  31 DEPEND="${RDEPEND}"
  32
  33 python_prepare_all() {
  34         # Plugins are voluntarily left automagic as application has a nice way
  35         # to suggest missing dependencies. We only remove the ones that cannot
  36         # work on gentoo.
  37         # Backends should be enabled via USE flag when pulling extra deps
  38
  39         # geoloc: uses removed from tree bindings
  40         sed -e "/GTG.plugins.geolocalized_tasks',/d" \
  41                 -e "/geolocalized-tasks.gtg-plugin/d" \
  42                 -i setup.py || die
  43
  44         # launchpad: missing dependency
  45         # evolution: missing python-r1 support
  46         rm GTG/backends/backend_launchpad.py \
  47                 GTG/backends/backend_evolution.py \
  48                 || die
  49
  50         # Respect LINGUAS
  51         epatch "${FILESDIR}"/${PN}-0.3.1-locales.patch
  52
  53         # Fix validation warning
  54         epatch "${FILESDIR}"/${PN}-0.3.1-desktop.patch
  55
  56         distutils-r1_python_prepare_all
  57 }
  58
  59 pkg_preinst() {
  60         gnome2_icon_savelist
  61 }
  62
  63 pkg_postinst() {
  64         fdo-mime_desktop_database_update
  65         fdo-mime_mime_database_update
  66         gnome2_icon_cache_update
  67 }
  68
  69 pkg_postrm() {
  70         fdo-mime_desktop_database_update
  71         fdo-mime_mime_database_update
  72         gnome2_icon_cache_update
  73 }