app-office/borg/borg-1.7.4-r3.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit versionator java-pkg-2 java-ant-2
   9
  10 MY_PN="${PN}_src"
  11 MY_PV="$(replace_all_version_separators _ )"
  12
  13 DESCRIPTION="Calendar and task tracker, written in Java"
  14 HOMEPAGE="http://borg-calendar.sourceforge.net/"
  15 SRC_URI="mirror://sourceforge/borg-calendar/borg%201.7/BORG%20${PV}/${MY_PN}_${MY_PV}.zip"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE=""
  21
  22 CDEPEND="
  23         dev-java/javahelp:0
  24         dev-java/oracle-javamail:0"
  25 RDEPEND="${CDEPEND}
  26         >=virtual/jre-1.6
  27         dev-db/hsqldb:0
  28         dev-java/jgoodies-looks:2.0"
  29 DEPEND="${CDEPEND}
  30         >=virtual/jdk-1.6
  31         app-arch/unzip"
  32
  33 S="${WORKDIR}/${MY_PN}/BORGCalendar"
  34
  35 java_prepare() {
  36         # Upstream is dead and we already have dev-java/jcalendar
  37         # but it's not the same thing.
  38         find -name '*.jar' -! -name 'jcalendar.jar' \
  39                 -exec rm -v {} + || die
  40 }
  41
  42 JAVA_ANT_REWRITE_CLASSPATH="yes"
  43 JAVA_ANT_CLASSPATH_TAGS+=" javadoc"
  44
  45 EANT_BUILD_XML="ant/build.xml"
  46 EANT_BUILD_TARGET="borg-jar help-jar"
  47 EANT_GENTOO_CLASSPATH="javahelp oracle-javamail"
  48
  49 src_install() {
  50         java-pkg_dojar dist/${PN}.jar
  51         java-pkg_dojar build/lib/${PN}help.jar
  52         java-pkg_dojar lib/jcalendar.jar
  53         java-pkg_register-dependency hsqldb,jgoodies-looks-2.0
  54
  55         java-pkg_dolauncher ${PN} --main net.sf.borg.control.Borg
  56
  57         use doc && java-pkg_dojavadoc docs
  58         use doc && java-pkg_dosrc src/*
  59 }