app-misc/radeontop/radeontop-1.2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit toolchain-funcs
   6
   7 DESCRIPTION="Utility to view Radeon GPU utilization"
   8 HOMEPAGE="https://github.com/clbr/radeontop"
   9 SRC_URI="https://github.com/clbr/radeontop/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  10
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="nls"
  15
  16 RDEPEND="
  17         sys-libs/ncurses:0=
  18         x11-libs/libdrm
  19         x11-libs/libpciaccess
  20         x11-libs/libxcb
  21         nls? (
  22                 sys-libs/ncurses:0=[unicode]
  23                 virtual/libintl
  24         )
  25 "
  26 DEPEND="${RDEPEND}
  27         nls? ( sys-devel/gettext )
  28 "
  29 BDEPEND="virtual/pkgconfig"
  30
  31 src_prepare() {
  32         default
  33
  34         cat > include/version.h <<-EOF || die
  35                 #ifndef VER_H
  36                 #define VER_H
  37
  38                 #define VERSION "${PV}"
  39
  40                 #endif
  41         EOF
  42         >getver.sh || die
  43         touch .git || die
  44 }
  45
  46 src_configure() {
  47         tc-export CC
  48         export LIBDIR=$(get_libdir)
  49         export nls=$(usex nls 1 0)
  50         export amdgpu=1
  51         export xcb=1
  52         # Do not add -g or -s to CFLAGS
  53         export plain=1
  54 }