app-misc/linux-logo/linux-logo-6.0.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 inherit toolchain-funcs systemd
   6
   7 MY_P=${PN/-/_}-${PV}
   8 DESCRIPTION="A utility that displays an ANSI/ASCII logo and some system information"
   9 HOMEPAGE="http://www.deater.net/weave/vmwprod/linux_logo/"
  10 SRC_URI="http://www.deater.net/weave/vmwprod/linux_logo/${MY_P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="~amd64 ~arm ~arm64 ~hppa ~ia64 ~mips ~ppc ~sparc ~x86 ~amd64-linux ~x86-linux"
  15 IUSE="nls"
  16
  17 RDEPEND="nls? ( virtual/libintl )"
  18 DEPEND="${RDEPEND}"
  19 BDEPEND="nls? ( sys-devel/gettext )"
  20
  21 PATCHES=(
  22         "${FILESDIR}"/"${P}"-configure.patch
  23 )
  24
  25 DOCS=( BUGS README README.CUSTOM_LOGOS TODO USAGE LINUX_LOGO.FAQ )
  26
  27 S=${WORKDIR}/${MY_P}
  28
  29 src_prepare() {
  30         cp "${FILESDIR}"/logo-config "${S}/logo_config" || die
  31         cp "${FILESDIR}"/linux_logo_creator "${S}/" || die
  32         cp "${FILESDIR}"/linux-logo.service "${S}/" || die
  33         cp "${FILESDIR}"/gentoo-*.logo "${S}"/logos/ || die
  34
  35         sed -e 's#=$(PREFIX)#=$(DESTDIR)$(PREFIX)#' -i po/Makefile || die
  36         default
  37 }
  38
  39 src_configure() {
  40         ARCH="" CC="$(tc-getCC)" AR="$(tc-getAR)" LDFLAGS="${LDFLAGS}" DESTDIR="${D}" \
  41                 ./configure --prefix=/usr || die
  42 }
  43
  44 src_install() {
  45         default
  46
  47         dobin "${FILESDIR}"/linux_logo_creator
  48         newinitd "${FILESDIR}"/${PN}.init.d ${PN}
  49         newconfd "${FILESDIR}"/${PN}-5.11.conf ${PN}
  50
  51         # systemd support
  52         systemd_newunit "${FILESDIR}/linux-logo.service" "linux-logo.service"
  53 }
  54
  55 pkg_postinst() {
  56         echo
  57         elog "Linux_logo ebuild for Gentoo comes with two Gentoo logos."
  58         elog ""
  59         elog "To display the first Gentoo logo type: linux_logo -L gentoo"
  60         elog "To display the second Gentoo logo type: linux_logo -L gentoo-alt"
  61         elog "To display all the logos available type: linux_logo -L list."
  62         elog ""
  63         elog "To start linux_logo on boot, please type:"
  64         elog "   rc-update add linux-logo default"
  65         elog "or for systemd"
  66         elog "   systemctl enable linux-logo.service"
  67         elog "which uses the settings found in"
  68         elog "   /etc/conf.d/linux-logo"
  69         echo
  70 }
  71
  72 pkg_prerm() {
  73         # Restore issue files
  74         mv /etc/issue.linux-logo.backup /etc/issue 2> /dev/null
  75         mv /etc/issue.net.linux-logo.backup /etc/issue.net 2> /dev/null
  76 }