app-leechcraft/lc-lmp/lc-lmp-9999.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit xdg-utils leechcraft
   7
   8 DESCRIPTION="LeechCraft Media Player, Phonon-based audio/video player"
   9
  10 SLOT="0"
  11 KEYWORDS=""
  12 IUSE="debug +fradj +graffiti +mpris +mtp +mp3tunes potorchu"
  13
  14 DEPEND="
  15         ~app-leechcraft/lc-core-${PV}
  16         dev-qt/qtconcurrent:5
  17         dev-qt/qtdeclarative:5[widgets]
  18         dev-qt/qtnetwork:5
  19         dev-qt/qtsql:5
  20         dev-qt/qtwidgets:5
  21         dev-qt/qtxml:5
  22         media-libs/gstreamer:1.0
  23         media-libs/taglib
  24         mpris? ( dev-qt/qtdbus:5 )
  25         mtp? ( media-libs/libmtp:= )
  26         potorchu? ( media-libs/libprojectm:= )
  27 "
  28 RDEPEND="${DEPEND}
  29         dev-qt/qtsql:5[sqlite]
  30         graffiti? ( media-libs/flac )
  31         mtp? ( ~app-leechcraft/lc-devmon-${PV} )
  32 "
  33
  34 src_configure() {
  35         local mycmakeargs=(
  36                 -DENABLE_LMP_LIBGUESS=OFF
  37                 -DENABLE_LMP_FRADJ=$(usex fradj)
  38                 -DENABLE_LMP_GRAFFITI=$(usex graffiti)
  39                 -DENABLE_LMP_MP3TUNES=$(usex mp3tunes)
  40                 -DENABLE_LMP_MPRIS=$(usex mpris)
  41                 -DENABLE_LMP_MTPSYNC=$(usex mtp)
  42                 -DENABLE_LMP_POTORCHU=$(usex potorchu)
  43         )
  44         cmake_src_configure
  45 }
  46
  47 pkg_postinst() {
  48         xdg_desktop_database_update
  49 }
  50
  51 pkg_postrm() {
  52         xdg_desktop_database_update
  53 }