app-laptop/pommed/pommed-1.39-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 inherit eutils toolchain-funcs linux-info systemd
   6
   7 DESCRIPTION="Manage screen and keyboard backlight on Apple MacBook Pro/PowerBook"
   8 HOMEPAGE="http://technologeek.org/projects/pommed/index.html"
   9 ALIOTH_NUMBER="3583"
  10 SRC_URI="http://alioth.debian.org/frs/download.php/${ALIOTH_NUMBER}/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 ppc x86"
  15 IUSE="gtk X"
  16
  17 COMMON_DEPEND="media-libs/alsa-lib
  18         x86? ( sys-apps/pciutils )
  19         amd64? (  sys-apps/pciutils )
  20         dev-libs/confuse
  21         >=sys-apps/dbus-1.1
  22         dev-libs/dbus-glib
  23         sys-libs/zlib
  24         media-libs/audiofile
  25         gtk? ( x11-libs/gtk+:2 )
  26         X? ( x11-libs/libX11
  27                 x11-libs/libXext
  28                 x11-libs/libXpm )"
  29 DEPEND="${COMMON_DEPEND}
  30         virtual/pkgconfig"
  31 RDEPEND="${COMMON_DEPEND}
  32         media-sound/alsa-utils
  33         virtual/eject"
  34
  35 pkg_setup() {
  36         if ! use ppc; then
  37                 linux-info_pkg_setup
  38
  39                 CONFIG_CHECK="~DMIID"
  40                 check_extra_config
  41         fi
  42 }
  43
  44 src_prepare() {
  45         epatch "${FILESDIR}/${P}.patch"
  46 }
  47
  48 src_compile() {
  49         cd "${S}"/pommed
  50         emake CC="$(tc-getCC)" OFLIB=1 || die "emake pommed failed"
  51
  52         if use gtk; then
  53                 cd "${S}"/gpomme
  54                 local POFILES=""
  55                 for LANG in ${LINGUAS}; do
  56                         if [ -f po/${LANG}.po ]; then
  57                                 POFILES="${POFILES} po/${LANG}.po"
  58                         fi
  59                 done
  60                 emake CC="$(tc-getCC)" POFILES="${POFILES}" || die "emake gpomme failed"
  61         fi
  62         if use X; then
  63                 cd "${S}"/wmpomme
  64                 emake CC="$(tc-getCC)" || die "emake wmpomme failed"
  65         fi
  66 }
  67
  68 src_install() {
  69         insinto /etc
  70         if use x86 || use amd64; then
  71                 newins pommed.conf.mactel pommed.conf
  72         elif use ppc; then
  73                 newins pommed.conf.pmac pommed.conf
  74         fi
  75
  76         insinto /etc/dbus-1/system.d
  77         newins dbus-policy.conf pommed.conf
  78
  79         insinto /usr/share/pommed
  80         doins pommed/data/*.wav
  81
  82         dobin pommed/pommed
  83
  84         newinitd "${FILESDIR}"/pommed.rc pommed
  85         systemd_dounit "${FILESDIR}"/${PN}.service
  86
  87         dodoc AUTHORS ChangeLog README TODO
  88
  89         if use gtk ; then
  90                 dobin gpomme/gpomme
  91                 for LANG in ${LINGUAS}; do
  92                         if [ -f gpomme/po/${LANG}.mo ]; then
  93                                 einfo "Installing lang ${LANG}"
  94                                 insinto /usr/share/locale/${LANG}/LC_MESSAGES/
  95                                 doins gpomme/po/${LANG}.mo
  96                         fi
  97                 done
  98
  99                 domenu gpomme/gpomme.desktop gpomme/gpomme-c.desktop
 100                 insinto /usr/share/gpomme/
 101                 doins -r gpomme/themes
 102         fi
 103
 104         if use X ; then
 105                 dobin wmpomme/wmpomme
 106         fi
 107 }