app-laptop/laptop-mode-tools/laptop-mode-tools-1.69.1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit eutils multilib systemd udev
   7
   8 MY_P=${PN}_${PV}
   9
  10 DESCRIPTION="Linux kernel laptop_mode user-space utilities"
  11 HOMEPAGE="https://github.com/rickysarraf/laptop-mode-tools/wiki"
  12 SRC_URI="https://github.com/rickysarraf/${PN}/releases/download/${PV}/${MY_P}.tar.gz"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc ~x86"
  17 IUSE="+acpi apm bluetooth scsi"
  18
  19 RDEPEND="net-wireless/wireless-tools
  20         sys-apps/iproute2
  21         sys-apps/ethtool
  22         sys-apps/hdparm
  23         sys-apps/which
  24         acpi? ( sys-power/acpid )
  25         apm? ( sys-apps/apmd )
  26         bluetooth? ( net-wireless/bluez:= )
  27         scsi? ( sys-apps/sdparm )"
  28 DEPEND=""
  29
  30 S=${WORKDIR}/${MY_P}
  31
  32 src_prepare() {
  33         # This should avoid conflict with pm-powersave wrt #327443 and #396703
  34         cat <<-EOF > "${T}"/${PN}
  35         HOOK_BLACKLIST="00powersave"
  36         EOF
  37 }
  38
  39 src_compile() { :; }
  40
  41 src_install() {
  42         DESTDIR="${D}" \
  43                 INIT_D="none" \
  44                 MAN_D="/usr/share/man" \
  45                 LIB_D="/usr/$(get_libdir)" \
  46                 UDEV_D="$(get_udevdir)" \
  47                 SYSTEMD_UNIT_D="$(systemd_get_unitdir)" \
  48                 TMPFILES_D="/usr/lib/tmpfiles.d" \
  49                 ACPI="$(use acpi && echo force || echo disabled)" \
  50                 PMU="$(false && echo force || echo disabled)" \
  51                 APM="$(use apm && echo force || echo disabled)" \
  52                 SYSTEMD=yes \
  53                 sh ./install.sh || die
  54
  55         dodoc Documentation/*.txt README.md
  56         newinitd "${FILESDIR}"/laptop_mode.init-1.4 laptop_mode
  57
  58         # See src_prepare()
  59         insinto /etc/pm/config.d
  60         doins "${T}"/${PN}
  61 }
  62
  63 pkg_postinst() {
  64         if use acpi || use apm; then
  65                 if use acpi; then
  66                         daemon_name="acpid"
  67                 elif use apm; then
  68                         deamon_name="apmd"
  69                 fi
  70                 if [ "$(rc-config list default | grep laptop_mode)" = "" ] || [ "$(rc-config list default | grep ${daemon_name} )" = "" ]; then
  71                         ewarn "To enable automatic power state event handling,"
  72                         ewarn "e.g. enabling laptop_mode after unplugging the battery,"
  73                         ewarn "both laptop_mode and the ${daemon_name} daemon must be"
  74                         ewarn "added to default runlevel:"
  75                         if [ "$(rc-config list default | grep laptop_mode)" = "" ]; then
  76                                 ewarn "# rc-update add laptop_mode default"
  77                         fi
  78                         if [ "$(rc-config list default | grep ${daemon_name} )" = "" ]; then
  79                                 ewarn "# rc-update add ${daemon_name} default"
  80                         fi
  81                 fi
  82         else
  83                 ewarn "Without USE=\"acpi\" or USE=\"apm\" ${PN} can not"
  84                 ewarn "automatically disable laptop_mode on low battery."
  85                 ewarn
  86                 ewarn "This means you can lose up to 10 minutes of work if running"
  87                 ewarn "out of battery while laptop_mode is enabled."
  88                 ewarn
  89                 ewarn "Please see laptop-mode.txt in /usr/share/doc/${PF} for further"
  90                 ewarn "information."
  91                 ewarn
  92         fi
  93 }