app-laptop/i8kutils/i8kutils-1.33-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=4
   5
   6 inherit systemd toolchain-funcs
   7
   8 DESCRIPTION="Dell Inspiron and Latitude utilities"
   9 HOMEPAGE="http://packages.debian.org/sid/i8kutils"
  10 SRC_URI="mirror://debian/pool/main/i/${PN}/${P/-/_}.tar.gz"
  11
  12 LICENSE="GPL-3"
  13 SLOT="0"
  14 KEYWORDS="-* amd64 x86"
  15 IUSE="examples tk"
  16
  17 DEPEND="tk? ( dev-lang/tk )"
  18 RDEPEND="${DEPEND}"
  19
  20 DOCS=( README.i8kutils )
  21
  22 src_prepare() {
  23         sed \
  24                 -e '/^CC/d' \
  25                 -e '/^CFLAGS/d' \
  26                 -e 's: -g : $(LDFLAGS) :g' \
  27                 -i Makefile || die
  28
  29         tc-export CC
  30 }
  31
  32 src_install() {
  33         dobin i8kbuttons i8kctl
  34         doman i8kbuttons.1 i8kctl.1
  35         dosym /usr/bin/i8kctl /usr/bin/i8kfan
  36
  37         use examples && dodoc -r examples
  38
  39         newinitd "${FILESDIR}"/i8k.init-r1 i8k
  40         newconfd "${FILESDIR}"/i8k.conf i8k
  41
  42         if use tk; then
  43                 dobin i8kmon
  44                 doman i8kmon.1
  45                 dodoc i8kmon.conf
  46                 systemd_dounit "${FILESDIR}"/i8kmon.service
  47         else
  48                 cat >> "${ED}"/etc/conf.d/i8k <<- EOF
  49                 # i8kmon disabled because the package was installed without USE=tk
  50                 NOMON=1
  51                 EOF
  52         fi
  53
  54 }