app-forensics/zzuf/zzuf-0.13-r1.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=4
   6
   7 inherit autotools eutils
   8
   9 DESCRIPTION="Transparent application input fuzzer"
  10 HOMEPAGE="http://libcaca.zoy.org/wiki/zzuf/"
  11 SRC_URI="http://caca.zoy.org/files/${PN}/${P}.tar.gz
  12         https://dev.gentoo.org/~cardoe/distfiles/${P}-zzcat-zzat-rename.patch.bz2"
  13
  14 LICENSE="WTFPL-2"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~sparc ~x86"
  17 IUSE=""
  18
  19 # fails with sandbox enabled
  20 RESTRICT="test"
  21
  22 DOCS=( AUTHORS ChangeLog NEWS README TODO )
  23
  24 src_prepare() {
  25         sed -i -e '/CFLAGS/d' "${S}"/configure.ac \
  26                 || die "unable to fix the configure.ac"
  27         sed -i -e 's:noinst_:check_:' "${S}"/test/Makefile.am \
  28                 || die "unable to fix unconditional test building"
  29
  30         epatch "${DISTDIR}"/${P}-zzcat-zzat-rename.patch.bz2
  31
  32         eautoreconf
  33 }
  34
  35 src_configure() {
  36         # Don't build the static library, as the library is only used for
  37         # preloading, so there is no reason to build it statically, unless
  38         # you want to use zzuf with a static-linked executable, which I'm
  39         # not even sure would be a good idea.
  40         econf --disable-static
  41 }
  42
  43 src_install() {
  44         default
  45
  46         find "${D}" -name '*.la' -delete
  47 }