app-forensics/afflib/afflib-3.7.18.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5 PYTHON_COMPAT=( python{2_7,3_{6,7}} )
   6
   7 inherit autotools python-single-r1
   8
   9 MY_PN=AFFLIBv3
  10 MY_P="${MY_PN}-${PV}"
  11
  12 DESCRIPTION="Library that implements the AFF image standard"
  13 HOMEPAGE="https://github.com/sshock/AFFLIBv3/"
  14 SRC_URI="https://github.com/sshock/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  15
  16 LICENSE="BSD"
  17 SLOT="0"
  18 KEYWORDS="amd64 ~arm hppa ppc x86 ~x64-macos"
  19 IUSE="fuse libressl ncurses python qemu readline s3 static-libs threads"
  20 REQUIRED_USE="python? ( ${PYTHON_REQUIRED_USE} )"
  21
  22 RDEPEND="
  23         dev-libs/expat
  24         sys-libs/zlib:0=
  25         fuse? ( sys-fs/fuse:= )
  26         !libressl? ( dev-libs/openssl:0= )
  27         libressl? ( dev-libs/libressl:= )
  28         ncurses? ( sys-libs/ncurses:0= )
  29         python? ( ${PYTHON_DEPS} )
  30         readline? ( sys-libs/readline:0= )
  31         s3? ( net-misc/curl )
  32 "
  33 DEPEND="${RDEPEND}"
  34
  35 S="${WORKDIR}/${MY_P}"
  36
  37 pkg_setup() {
  38         use python && python-single-r1_pkg_setup
  39 }
  40
  41 src_prepare() {
  42         sed -i '/FLAGS/s: -g::' configure.ac || die
  43
  44         default
  45         eautoreconf
  46 }
  47
  48 src_configure() {
  49         # Hacks for automagic dependencies
  50         use ncurses || export ac_cv_lib_ncurses_initscr=no
  51         use readline || export ac_cv_lib_readline_readline=no
  52
  53         local myeconfargs=(
  54                 $(use_enable fuse)
  55                 $(use_enable python)
  56                 $(use_enable qemu)
  57                 $(use_enable s3)
  58                 $(use_enable static-libs static)
  59                 $(use_enable threads threading)
  60         )
  61         econf "${myeconfargs[@]}"
  62 }
  63
  64 src_install() {
  65         default
  66         find "${ED}" -name "*.la" -delete || die
  67 }