app-eselect/eselect-repository/eselect-repository-7.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python{3_6,3_7,3_8} )
   7 inherit python-single-r1
   8
   9 DESCRIPTION="Manage repos.conf via eselect"
  10 HOMEPAGE="https://github.com/mgorny/eselect-repository"
  11 SRC_URI="https://github.com/mgorny/eselect-repository/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  12
  13 LICENSE="BSD-2"
  14 SLOT="0"
  15 KEYWORDS="~alpha amd64 arm ~arm64 ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc x86"
  16 IUSE=""
  17 REQUIRED_USE=${PYTHON_REQUIRED_USE}
  18
  19 RDEPEND="${PYTHON_DEPS}
  20         app-admin/eselect
  21         $(python_gen_cond_dep '
  22                 dev-python/lxml[${PYTHON_MULTI_USEDEP}]
  23         ')
  24         net-misc/wget"
  25
  26 src_compile() {
  27         MAKEARGS=(
  28                 PREFIX="${EPREFIX}/usr"
  29                 SYSCONFDIR="${EPREFIX}/etc"
  30                 SHAREDSTATEDIR="${EPREFIX}/var"
  31                 ESELECTDIR="${EPREFIX}/usr/share/eselect/modules"
  32         )
  33
  34         emake "${MAKEARGS[@]}"
  35         python_fix_shebang eselect-repo-helper
  36 }
  37
  38 src_install() {
  39         emake "${MAKEARGS[@]}" DESTDIR="${D}" install
  40         keepdir /var/db/repos
  41         einstalldocs
  42 }