app-eselect/eselect-php/eselect-php-0.9.2.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit systemd
   7
   8 DESCRIPTION="PHP eselect module"
   9 HOMEPAGE="https://gitweb.gentoo.org/proj/eselect-php.git/"
  10 SRC_URI="https://dev.gentoo.org/~mjo/distfiles/${P}.tar.xz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="alpha amd64 arm ~arm64 hppa ia64 ~mips ppc ppc64 ~s390 ~sh sparc x86 ~amd64-fbsd ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos"
  15 IUSE="fpm apache2"
  16
  17 # The "DirectoryIndex" line in 70_mod_php.conf requires mod_dir.
  18 RDEPEND="app-admin/eselect
  19         apache2? ( www-servers/apache[apache2_modules_dir] )"
  20
  21 src_configure(){
  22         # We expect localstatedir to be "var"ish, not "var/lib"ish, because
  23         # that's what PHP upstream expects. See for example the FPM
  24         # configuration where they put logs in @localstatedir@/log.
  25         econf --localstatedir="${EPREFIX}"/var $(use_enable apache2)
  26 }
  27
  28 src_install() {
  29         default
  30
  31         # This can be removed after a while...
  32         if use apache2 ; then
  33                 insinto /etc/apache2/modules.d
  34                 newins "${FILESDIR}/70_mod_php5.backcompat.conf" 70_mod_php5.conf
  35         fi
  36
  37         if use fpm ; then
  38                 newinitd "doc/php-fpm.example.init" "php-fpm"
  39                 newconfd "doc/php-fpm.example.conf" "php-fpm"
  40                 systemd_dotmpfilesd "${FILESDIR}/php-fpm.conf"
  41                 exeinto /usr/libexec
  42                 doexe "${FILESDIR}/php-fpm-launcher"
  43         fi
  44 }
  45
  46 pkg_postinst() {
  47         if use apache2 ; then
  48                 elog
  49                 elog "If you are upgrading, be warned that our mod_php configuration"
  50                 elog "file has changed! You should now define -DPHP for the apache2"
  51                 elog "daemon, and inspect the new 70_mod_php.conf which has been"
  52                 elog "installed. Module loading involves eselect as of this version."
  53                 elog
  54                 elog "You must run eselect at least once to choose your apache2 target"
  55                 elog "before the new configuration will work. Afterwards, and after you"
  56                 elog "have reviewed your new configuration, you are advised to remove"
  57                 elog "the obsolete 70_mod_php5.conf file."
  58                 elog
  59         fi
  60 }