app-emulation/virtualbox/virtualbox-5.2.34.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 inherit flag-o-matic gnome2-utils java-pkg-opt-2 linux-info pax-utils python-single-r1 tmpfiles toolchain-funcs udev xdg-utils
   8
   9 MY_PV="${PV/beta/BETA}"
  10 MY_PV="${MY_PV/rc/RC}"
  11 MY_P=VirtualBox-${MY_PV}
  12
  13 DESCRIPTION="Family of powerful x86 virtualization products for enterprise and home use"
  14 HOMEPAGE="https://www.virtualbox.org/"
  15 SRC_URI="https://download.virtualbox.org/virtualbox/${MY_PV}/${MY_P}.tar.bz2
  16         https://dev.gentoo.org/~polynomial-c/${PN}/patchsets/${PN}-5.2.34-patches-01.tar.xz"
  17
  18 LICENSE="GPL-2 dtrace? ( CDDL )"
  19 SLOT="0"
  20 KEYWORDS="~amd64 ~x86"
  21 IUSE="alsa debug doc dtrace headless java libressl lvm pam pax_kernel pulseaudio +opengl python +qt5 +sdk +udev vboxwebsrv vnc"
  22
  23 RDEPEND="!app-emulation/virtualbox-bin
  24         ~app-emulation/virtualbox-modules-${PV}
  25         dev-libs/libIDL
  26         >=dev-libs/libxslt-1.1.19
  27         net-misc/curl
  28         dev-libs/libxml2
  29         media-libs/libpng:0=
  30         media-libs/libvpx:0=
  31         media-libs/opus
  32         sys-libs/zlib:=
  33         !headless? (
  34                 media-libs/libsdl:0[X,video]
  35                 x11-libs/libX11
  36                 x11-libs/libxcb:=
  37                 x11-libs/libXcursor
  38                 x11-libs/libXext
  39                 x11-libs/libXmu
  40                 x11-libs/libXt
  41                 opengl? ( virtual/opengl media-libs/freeglut )
  42                 qt5? (
  43                         dev-qt/qtcore:5
  44                         dev-qt/qtgui:5
  45                         dev-qt/qtprintsupport:5
  46                         dev-qt/qtwidgets:5
  47                         dev-qt/qtx11extras:5
  48                         opengl? ( dev-qt/qtopengl:5 )
  49                         x11-libs/libXinerama
  50                 )
  51         )
  52         libressl? ( dev-libs/libressl:= )
  53         !libressl? ( dev-libs/openssl:0= )
  54         lvm? ( sys-fs/lvm2 )
  55         udev? ( >=virtual/udev-171 )
  56         vnc? ( >=net-libs/libvncserver-0.9.9 )
  57         ${PYTHON_DEPS}"
  58 DEPEND="${RDEPEND}
  59         >=dev-util/kbuild-0.1.9998.3127
  60         >=dev-lang/yasm-0.6.2
  61         sys-devel/bin86
  62         sys-libs/libcap
  63         sys-power/iasl
  64         virtual/pkgconfig
  65         alsa? ( >=media-libs/alsa-lib-1.0.13 )
  66         doc? (
  67                 app-text/docbook-sgml-dtd:4.4
  68                 dev-texlive/texlive-basic
  69                 dev-texlive/texlive-latex
  70                 dev-texlive/texlive-latexrecommended
  71                 dev-texlive/texlive-latexextra
  72                 dev-texlive/texlive-fontsrecommended
  73                 dev-texlive/texlive-fontsextra
  74         )
  75         !headless? ( x11-libs/libXinerama )
  76         java? ( >=virtual/jdk-1.6 )
  77         pam? ( sys-libs/pam )
  78         pax_kernel? ( sys-apps/elfix )
  79         pulseaudio? ( media-sound/pulseaudio )
  80         qt5? ( dev-qt/linguist-tools:5 )
  81         vboxwebsrv? ( net-libs/gsoap[-gnutls(-)] )
  82         ${PYTHON_DEPS}"
  83 RDEPEND="${RDEPEND}
  84         java? ( >=virtual/jre-1.6 )"
  85
  86 QA_TEXTRELS_x86="usr/lib/virtualbox-ose/VBoxGuestPropSvc.so
  87         usr/lib/virtualbox/VBoxSDL.so
  88         usr/lib/virtualbox/VBoxSharedFolders.so
  89         usr/lib/virtualbox/VBoxDD2.so
  90         usr/lib/virtualbox/VBoxOGLrenderspu.so
  91         usr/lib/virtualbox/VBoxPython.so
  92         usr/lib/virtualbox/VBoxDD.so
  93         usr/lib/virtualbox/VBoxDDU.so
  94         usr/lib/virtualbox/VBoxREM64.so
  95         usr/lib/virtualbox/VBoxSharedClipboard.so
  96         usr/lib/virtualbox/VBoxHeadless.so
  97         usr/lib/virtualbox/VBoxRT.so
  98         usr/lib/virtualbox/VBoxREM.so
  99         usr/lib/virtualbox/VBoxSettings.so
 100         usr/lib/virtualbox/VBoxKeyboard.so
 101         usr/lib/virtualbox/VBoxSharedCrOpenGL.so
 102         usr/lib/virtualbox/VBoxVMM.so
 103         usr/lib/virtualbox/VirtualBox.so
 104         usr/lib/virtualbox/VBoxOGLhosterrorspu.so
 105         usr/lib/virtualbox/components/VBoxC.so
 106         usr/lib/virtualbox/components/VBoxSVCM.so
 107         usr/lib/virtualbox/components/VBoxDDU.so
 108         usr/lib/virtualbox/components/VBoxRT.so
 109         usr/lib/virtualbox/components/VBoxREM.so
 110         usr/lib/virtualbox/components/VBoxVMM.so
 111         usr/lib/virtualbox/VBoxREM32.so
 112         usr/lib/virtualbox/VBoxPython2_7.so
 113         usr/lib/virtualbox/VBoxXPCOMC.so
 114         usr/lib/virtualbox/VBoxOGLhostcrutil.so
 115         usr/lib/virtualbox/VBoxNetDHCP.so
 116         usr/lib/virtualbox/VBoxNetNAT.so"
 117
 118 S="${WORKDIR}/${MY_P}"
 119
 120 REQUIRED_USE="
 121         java? ( sdk )
 122         python? ( sdk )
 123         vboxwebsrv? ( java )
 124         ${PYTHON_REQUIRED_USE}
 125 "
 126
 127 pkg_pretend() {
 128         if ! use headless && ! use qt5 ; then
 129                 einfo "No USE=\"qt5\" selected, this build will not include any Qt frontend."
 130         elif use headless && use qt5 ; then
 131                 einfo "You selected USE=\"headless qt5\", defaulting to"
 132                 einfo "USE=\"headless\", this build will not include any X11/Qt frontend."
 133         fi
 134
 135         if ! use opengl ; then
 136                 einfo "No USE=\"opengl\" selected, this build will lack"
 137                 einfo "the OpenGL feature."
 138         fi
 139         if ! use python ; then
 140                 einfo "You have disabled the \"python\" USE flag. This will only"
 141                 einfo "disable the python bindings being installed."
 142         fi
 143 }
 144
 145 pkg_setup() {
 146         java-pkg-opt-2_pkg_setup
 147         python-single-r1_pkg_setup
 148
 149         tc-ld-disable-gold #bug 488176
 150         tc-export CC CXX LD AR RANLIB
 151         export HOST_CC="$(tc-getBUILD_CC)"
 152 }
 153
 154 src_prepare() {
 155         # Remove shipped binaries (kBuild,yasm), see bug #232775
 156         rm -r kBuild/bin tools || die
 157
 158         # Replace pointless GCC version check with something less stupid.
 159         # This is needed for the qt5 version check.
 160         sed -e 's@^check_gcc$@cc_maj="$(gcc -dumpversion | cut -d. -f1)" ; cc_min="$(gcc -dumpversion | cut -d. -f2)"@' \
 161                 -i configure || die
 162
 163         # Disable things unused or split into separate ebuilds
 164         sed -e "s@MY_LIBDIR@$(get_libdir)@" \
 165                 "${FILESDIR}"/${PN}-5-localconfig > LocalConfig.kmk || die
 166
 167         # Respect LDFLAGS
 168         sed -e "s@_LDFLAGS\.${ARCH}*.*=@& ${LDFLAGS}@g" \
 169                 -i Config.kmk src/libs/xpcom18a4/Config.kmk || die
 170
 171         # Do not use hard-coded ld (related to bug #488176)
 172         sed -e '/QUIET)ld /s@ld @$(LD) @' \
 173                 -i src/VBox/Devices/PC/ipxe/Makefile.kmk || die
 174
 175         # Use PAM only when pam USE flag is enbaled (bug #376531)
 176         if ! use pam ; then
 177                 elog "Disabling PAM removes the possibility to use the VRDP features."
 178                 sed -i 's@^.*VBOX_WITH_PAM@#VBOX_WITH_PAM@' Config.kmk || die
 179                 sed -i 's@\(.*/auth/Makefile.kmk.*\)@#\1@' \
 180                         src/VBox/HostServices/Makefile.kmk || die
 181         fi
 182
 183         # add correct java path
 184         if use java ; then
 185                 sed "s@/usr/lib/jvm/java-6-sun@$(java-config -O)@" \
 186                         -i "${S}"/Config.kmk || die
 187                 java-pkg-opt-2_src_prepare
 188         fi
 189
 190         # Only add nopie patch when we're on hardened
 191         if  gcc-specs-pie ; then
 192                 eapply "${FILESDIR}/050_virtualbox-5.2.8-nopie.patch"
 193         fi
 194
 195         # Only add paxmark patch when we're on pax_kernel
 196         if use pax_kernel ; then
 197                 eapply "${FILESDIR}"/virtualbox-5.2.8-paxmark-bldprogs.patch
 198         fi
 199
 200         rm "${WORKDIR}/patches/008_virtualbox-4.3.14-missing_define.patch" || die
 201         eapply "${WORKDIR}/patches"
 202
 203         eapply_user
 204 }
 205
 206 doecho() {
 207         echo "$@"
 208         "$@" || die
 209 }
 210
 211 src_configure() {
 212         local myconf=(
 213                 --with-gcc="$(tc-getCC)"
 214                 --with-g++="$(tc-getCXX)"
 215                 --disable-dbus
 216                 --disable-kmods
 217                 $(usex alsa '' --disable-alsa)
 218                 $(usex debug --build-debug '')
 219                 $(usex doc '' --disable-docs)
 220                 $(usex java '' --disable-java)
 221                 $(usex lvm '' --disable-devmapper)
 222                 $(usex pulseaudio '' --disable-pulse)
 223                 $(usex python '' --disable-python)
 224                 $(usex vboxwebsrv --enable-webservice '')
 225                 $(usex vnc --enable-vnc '')
 226         )
 227         if ! use headless ; then
 228                 myconf+=(
 229                         $(usex opengl '' --disable-opengl)
 230                         $(usex qt5 '' --disable-qt)
 231                 )
 232         else
 233                 myconf+=(
 234                         --build-headless
 235                         --disable-opengl
 236                 )
 237         fi
 238         if use amd64 && ! has_multilib_profile ; then
 239                 myconf+=( --disable-vmmraw )
 240         fi
 241         # not an autoconf script
 242         doecho ./configure ${myconf[@]}
 243 }
 244
 245 src_compile() {
 246         source ./env.sh || die
 247
 248         # Force kBuild to respect C[XX]FLAGS and MAKEOPTS (bug #178529)
 249         MAKEJOBS=$(grep -Eo '(\-j|\-\-jobs)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS}) #'
 250         MAKELOAD=$(grep -Eo '(\-l|\-\-load-average)(=?|[[:space:]]*)[[:digit:]]+' <<< ${MAKEOPTS}) #'
 251         MAKEOPTS="${MAKEJOBS} ${MAKELOAD}"
 252         MAKE="kmk" emake \
 253                 VBOX_BUILD_PUBLISHER=_Gentoo \
 254                 TOOL_GCC3_CC="$(tc-getCC)" TOOL_GCC3_CXX="$(tc-getCXX)" \
 255                 TOOL_GCC3_AS="$(tc-getCC)" TOOL_GCC3_AR="$(tc-getAR)" \
 256                 TOOL_GCC3_LD="$(tc-getCXX)" TOOL_GCC3_LD_SYSMOD="$(tc-getLD)" \
 257                 TOOL_GCC3_CFLAGS="${CFLAGS}" TOOL_GCC3_CXXFLAGS="${CXXFLAGS}" \
 258                 VBOX_GCC_OPT="${CXXFLAGS}" \
 259                 TOOL_YASM_AS=yasm KBUILD_VERBOSE=2 \
 260                 all
 261 }
 262
 263 src_install() {
 264         local binpath="release"
 265         use debug && binpath="debug"
 266         cd "${S}"/out/linux.${ARCH}/${binpath}/bin || die
 267
 268         local vbox_inst_path="/usr/$(get_libdir)/${PN}" each fwfile size ico icofile
 269
 270         vbox_inst() {
 271                 local binary="${1}"
 272                 local perms="${2:-0750}"
 273                 local path="${3:-${vbox_inst_path}}"
 274
 275                 [[ -n "${binary}" ]] || die "vbox_inst: No binray given!"
 276                 [[ ${perms} =~ ^[[:digit:]]+{4}$ ]] || die "vbox_inst: perms must consist of four digits."
 277
 278                 insinto ${path}
 279                 doins ${binary}
 280                 fowners root:vboxusers ${path}/${binary}
 281                 fperms ${perms} ${path}/${binary}
 282         }
 283
 284         # Create configuration files
 285         insinto /etc/vbox
 286         newins "${FILESDIR}/${PN}-4-config" vbox.cfg
 287
 288         # Set the correct libdir
 289         sed \
 290                 -e "s@MY_LIBDIR@$(get_libdir)@" \
 291                 -i "${ED%/}"/etc/vbox/vbox.cfg || die "vbox.cfg sed failed"
 292
 293         # Install the wrapper script
 294         exeinto ${vbox_inst_path}
 295         newexe "${FILESDIR}/${PN}-ose-5-wrapper" "VBox"
 296         fowners root:vboxusers ${vbox_inst_path}/VBox
 297         fperms 0750 ${vbox_inst_path}/VBox
 298
 299         # Install binaries and libraries
 300         insinto ${vbox_inst_path}
 301         doins -r components
 302
 303         # *.rc files for x86_64 are only available on multilib systems
 304         local rcfiles="*.rc"
 305         if use amd64 && ! has_multilib_profile ; then
 306                 rcfiles=""
 307         fi
 308         for each in VBox{ExtPackHelperApp,Manage,SVC,Tunctl,XPCOMIPCD} *so *r0 ${rcfiles} ; do
 309                 vbox_inst ${each}
 310         done
 311
 312         # These binaries need to be suid root.
 313         for each in VBox{Headless,Net{AdpCtl,DHCP,NAT}} ; do
 314                 vbox_inst ${each} 4750
 315         done
 316
 317         # Install EFI Firmware files (bug #320757)
 318         pushd "${S}"/src/VBox/Devices/EFI/FirmwareBin &>/dev/null || die
 319         for fwfile in VBoxEFI{32,64}.fd ; do
 320                 vbox_inst ${fwfile} 0644
 321         done
 322         popd &>/dev/null || die
 323
 324         # VBoxSVC and VBoxManage need to be pax-marked (bug #403453)
 325         # VBoxXPCOMIPCD (bug #524202)
 326         for each in VBox{Headless,Manage,SVC,XPCOMIPCD} ; do
 327                 pax-mark -m "${ED%/}"${vbox_inst_path}/${each}
 328         done
 329
 330         # Symlink binaries to the shipped wrapper
 331         for each in vbox{headless,manage} VBox{Headless,Manage,VRDP} ; do
 332                 dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 333         done
 334         dosym ${vbox_inst_path}/VBoxTunctl /usr/bin/VBoxTunctl
 335
 336         if use pam ; then
 337                 # VRDPAuth only works with this (bug #351949)
 338                 dosym VBoxAuth.so ${vbox_inst_path}/VRDPAuth.so
 339         fi
 340
 341         # set an env-variable for 3rd party tools
 342         echo -n "VBOX_APP_HOME=${vbox_inst_path}" > "${T}/90virtualbox"
 343         doenvd "${T}/90virtualbox"
 344
 345         if ! use headless ; then
 346                 vbox_inst VBoxSDL 4750
 347                 pax-mark -m "${ED%/}"${vbox_inst_path}/VBoxSDL
 348
 349                 for each in vboxsdl VBoxSDL ; do
 350                         dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 351                 done
 352
 353                 if use qt5 ; then
 354                         vbox_inst VirtualBox 4750
 355                         pax-mark -m "${ED%/}"${vbox_inst_path}/VirtualBox
 356
 357                         if use opengl ; then
 358                                 vbox_inst VBoxTestOGL
 359                                 pax-mark -m "${ED%/}"${vbox_inst_path}/VBoxTestOGL
 360                         fi
 361
 362                         for each in virtualbox VirtualBox ; do
 363                                 dosym ${vbox_inst_path}/VBox /usr/bin/${each}
 364                         done
 365
 366                         insinto /usr/share/${PN}
 367                         doins -r nls
 368                         doins -r UnattendedTemplates
 369
 370                         newmenu "${FILESDIR}"/${PN}-ose.desktop-2 ${PN}.desktop
 371                 fi
 372
 373                 pushd "${S}"/src/VBox/Artwork/OSE &>/dev/null || die
 374                 for size in 16 32 48 64 128 ; do
 375                         newicon -s ${size} ${PN}-${size}px.png ${PN}.png
 376                 done
 377                 newicon ${PN}-48px.png ${PN}.png
 378                 doicon -s scalable ${PN}.svg
 379                 popd &>/dev/null || die
 380                 pushd "${S}"/src/VBox/Artwork/other &>/dev/null || die
 381                 for size in 16 24 32 48 64 72 96 128 256 512 ; do
 382                         for ico in hdd ova ovf vbox{,-extpack} vdi vdh vmdk ; do
 383                                 icofile="${PN}-${ico}-${size}px.png"
 384                                 if [[ -f "${icofile}" ]] ; then
 385                                         newicon -s ${size} ${icofile} ${PN}-${ico}.png
 386                                 fi
 387                         done
 388                 done
 389                 popd &>/dev/null || die
 390         fi
 391
 392         if use lvm ; then
 393                 vbox_inst VBoxVolInfo 4750
 394                 dosym ${vbox_inst_path}/VBoxVolInfo /usr/bin/VBoxVolInfo
 395         fi
 396
 397         if use sdk ; then
 398                 insinto ${vbox_inst_path}
 399                 doins -r sdk
 400
 401                 if use java ; then
 402                         java-pkg_regjar "${ED%/}/${vbox_inst_path}/sdk/bindings/xpcom/java/vboxjxpcom.jar"
 403                         java-pkg_regso "${ED%/}/${vbox_inst_path}/libvboxjxpcom.so"
 404                 fi
 405         fi
 406
 407         if use udev ; then
 408                 # New way of handling USB device nodes for VBox (bug #356215)
 409                 local udevdir="$(get_udevdir)"
 410                 insinto ${udevdir}
 411                 doins VBoxCreateUSBNode.sh
 412                 fowners root:vboxusers ${udevdir}/VBoxCreateUSBNode.sh
 413                 fperms 0750 ${udevdir}/VBoxCreateUSBNode.sh
 414                 insinto ${udevdir}/rules.d
 415                 sed "s@%UDEVDIR%@${udevdir}@" "${FILESDIR}"/10-virtualbox.rules \
 416                         > "${T}"/10-virtualbox.rules || die
 417                 doins "${T}"/10-virtualbox.rules
 418         fi
 419
 420         if use vboxwebsrv ; then
 421                 vbox_inst vboxwebsrv
 422                 dosym ${vbox_inst_path}/VBox /usr/bin/vboxwebsrv
 423                 newinitd "${FILESDIR}"/vboxwebsrv-initd vboxwebsrv
 424                 newconfd "${FILESDIR}"/vboxwebsrv-confd vboxwebsrv
 425         fi
 426
 427         # Fix version string in extensions or else they don't get accepted
 428         # by the virtualbox host process (see bug #438930)
 429         find ExtensionPacks -type f -name "ExtPack.xml" -print0 \
 430                 | xargs --no-run-if-empty --null sed -i '/Version/s@_Gentoo@@' \
 431                 || die
 432
 433         if use vnc ; then
 434                 insinto ${vbox_inst_path}/ExtensionPacks
 435                 doins -r ExtensionPacks/VNC
 436         fi
 437
 438         if use dtrace ; then
 439                 insinto ${vbox_inst_path}/ExtensionPacks
 440                 doins -r ExtensionPacks/Oracle_VBoxDTrace_Extension_Pack
 441         fi
 442
 443         if use doc ; then
 444                 dodoc UserManual.pdf
 445         fi
 446
 447         newtmpfiles "${FILESDIR}"/${PN}-vboxusb_tmpfilesd ${PN}-vboxusb.conf
 448 }
 449
 450 pkg_postinst() {
 451         gnome2_icon_cache_update
 452         xdg_desktop_database_update
 453
 454         if use udev ; then
 455                 udevadm control --reload-rules \
 456                         && udevadm trigger --subsystem-match=usb
 457         fi
 458
 459         tmpfiles_process /usr/lib/tmpfiles.d/virtualbox-vboxusb.conf
 460
 461         if ! use headless && use qt5 ; then
 462                 elog "To launch VirtualBox just type: \"virtualbox\"."
 463         fi
 464         elog "You must be in the vboxusers group to use VirtualBox."
 465         elog ""
 466         elog "The latest user manual is available for download at:"
 467         elog "http://download.virtualbox.org/virtualbox/${PV}/UserManual.pdf"
 468         elog ""
 469         elog "For advanced networking setups you should emerge:"
 470         elog "net-misc/bridge-utils and sys-apps/usermode-utilities"
 471         elog ""
 472         elog "Starting with version 4.0.0, ${PN} has USB-1 support."
 473         elog "For USB-2 support, PXE-boot ability and VRDP support please emerge"
 474         elog "  app-emulation/virtualbox-extpack-oracle"
 475         elog "package."
 476         elog "Starting with version 5.0.0, ${PN} no longer has the \"additions\" and"
 477         elog "the \"extension\" USE flag. For installation of the guest additions ISO"
 478         elog "image, please emerge"
 479         elog "  app-emulation/virtualbox-additions"
 480         elog "and for the USB2, USB3, VRDP and PXE boot ROM modules, please emerge"
 481         elog "  app-emulation/virtualbox-extpack-oracle"
 482         if ! use udev ; then
 483                 elog ""
 484                 elog "WARNING!"
 485                 elog "Without USE=udev, USB devices will likely not work in ${PN}."
 486         elif [ -e "${ROOT%/}/etc/udev/rules.d/10-virtualbox.rules" ] ; then
 487                 elog ""
 488                 elog "Please remove \"${ROOT%/}/etc/udev/rules.d/10-virtualbox.rules\""
 489                 elog "or else USB in ${PN} won't work."
 490         fi
 491 }
 492
 493 pkg_postrm() {
 494         gnome2_icon_cache_update
 495         xdg_desktop_database_update
 496 }