app-emulation/virt-manager/virt-manager-1.4.1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 PYTHON_COMPAT=( python2_7 )
   7 DISTUTILS_SINGLE_IMPL=1
   8
   9 inherit gnome2 distutils-r1
  10
  11 DESCRIPTION="A graphical tool for administering virtual machines"
  12 HOMEPAGE="http://virt-manager.org"
  13
  14 if [[ ${PV} = *9999* ]]; then
  15         inherit git-r3
  16         SRC_URI=""
  17         KEYWORDS=""
  18         EGIT_REPO_URI="https://github.com/virt-manager/virt-manager.git"
  19 else
  20         SRC_URI="http://virt-manager.org/download/sources/${PN}/${P}.tar.gz"
  21         KEYWORDS="~amd64 ~x86"
  22 fi
  23
  24 LICENSE="GPL-2"
  25 SLOT="0"
  26 IUSE="gnome-keyring gtk policykit sasl"
  27
  28 RDEPEND="!app-emulation/virtinst
  29         dev-python/libvirt-python[${PYTHON_USEDEP}]
  30         >=app-emulation/libvirt-glib-1.0.0[introspection]
  31         ${PYTHON_DEPS}
  32         dev-libs/libxml2[python,${PYTHON_USEDEP}]
  33         dev-python/ipaddr[${PYTHON_USEDEP}]
  34         dev-python/pygobject:3[${PYTHON_USEDEP}]
  35         dev-python/requests[${PYTHON_USEDEP}]
  36         >=sys-libs/libosinfo-0.2.10[introspection]
  37         gtk? (
  38                 x11-libs/gtk+:3[introspection]
  39                 gnome-base/dconf
  40                 >=net-libs/gtk-vnc-0.3.8[gtk3,introspection,python,${PYTHON_USEDEP}]
  41                 net-misc/spice-gtk[usbredir,gtk3,introspection,sasl?]
  42                 net-misc/x11-ssh-askpass
  43                 x11-libs/vte:2.91[introspection]
  44                 gnome-keyring? ( gnome-base/libgnome-keyring )
  45                 policykit? ( sys-auth/polkit[introspection] )
  46                 x11-themes/gnome-icon-theme
  47         )"
  48 DEPEND="${RDEPEND}
  49         dev-lang/perl
  50         dev-util/intltool"
  51
  52 DOCS=( README.md NEWS.md )
  53
  54 src_prepare() {
  55         distutils-r1_src_prepare
  56 }
  57
  58 distutils-r1_python_compile() {
  59         local defgraphics=
  60
  61         esetup.py configure \
  62                 --qemu-user=qemu \
  63                 --default-graphics=spice
  64 }
  65
  66 src_install() {
  67         local mydistutilsargs=( --no-update-icon-cache --no-compile-schemas )
  68
  69         distutils-r1_src_install
  70
  71         python_fix_shebang \
  72                 "${ED}"/usr/share/virt-manager/virt-{clone,convert,install,manager}
  73 }
  74
  75 pkg_preinst() {
  76         if use gtk; then
  77                 gnome2_pkg_preinst
  78
  79                 cd "${ED}"
  80                 export GNOME2_ECLASS_ICONS=$(find 'usr/share/virt-manager/icons' -maxdepth 1 -mindepth 1 -type d 2> /dev/null)
  81         else
  82                 rm -rf "${ED}/usr/share/virt-manager/virtManager"
  83                 rm -f "${ED}/usr/share/virt-manager/virt-manager"
  84                 rm -rf "${ED}/usr/share/virt-manager/ui/"
  85                 rm -rf "${ED}/usr/share/virt-manager/icons/"
  86                 rm -rf "${ED}/usr/share/man/man1/virt-manager.1*"
  87                 rm -rf "${ED}/usr/share/icons/"
  88                 rm -rf "${ED}/usr/share/applications/virt-manager.desktop"
  89                 rm -rf "${ED}/usr/bin/virt-manager"
  90         fi
  91 }
  92
  93 pkg_postinst() {
  94         use gtk && gnome2_pkg_postinst
  95 }