app-emulation/libspectrum/libspectrum-1.4.4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DESCRIPTION="Spectrum emulation library"
   7 HOMEPAGE="http://fuse-emulator.sourceforge.net/libspectrum.php"
   8 SRC_URI="mirror://sourceforge/fuse-emulator/${P}.tar.gz"
   9
  10 LICENSE="GPL-2"
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~ppc ~x86"
  13 IUSE="audiofile bzip2 gcrypt zlib"
  14
  15 RDEPEND="dev-libs/glib:2
  16         audiofile? ( >=media-libs/audiofile-0.3.6 )
  17         bzip2? ( >=app-arch/bzip2-1.0 )
  18         gcrypt? ( dev-libs/libgcrypt:0 )
  19         zlib? ( sys-libs/zlib )"
  20 DEPEND="${RDEPEND}
  21         dev-lang/perl
  22         virtual/pkgconfig"
  23
  24 src_configure() {
  25         local myconf=(
  26                 $(use_with audiofile libaudiofile)
  27                 $(use_with bzip2)
  28                 $(use_with gcrypt libgcrypt)
  29                 $(use_with zlib)
  30         )
  31         econf "${myconf[@]}"
  32 }
  33
  34 src_test() {
  35         # check only builds test executable but doesn't run it
  36         emake check
  37         ./test/test || die
  38 }
  39
  40 src_install() {
  41         default
  42         dodoc doc/*.txt *.txt
  43 }