app-emulation/hercules/hercules-3.12.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 inherit flag-o-matic eutils
   7
   8 DESCRIPTION="Hercules System/370, ESA/390 and zArchitecture Mainframe Emulator"
   9 HOMEPAGE="http://www.hercules-390.eu/"
  10 SRC_URI="http://downloads.hercules-390.eu/${P}.tar.gz"
  11
  12 LICENSE="QPL-1.0"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~ppc ~sparc ~x86 ~x64-macos ~x86-macos"
  15 IUSE="bzip2 custom-cflags +suid"
  16
  17 RDEPEND="bzip2? ( app-arch/bzip2 )
  18         net-libs/libnsl:0=
  19         sys-libs/zlib"
  20 DEPEND="${RDEPEND}"
  21
  22 src_prepare() {
  23         epatch "${FILESDIR}"/${PN}-3.09-aliasing.patch
  24
  25         # The local modules need local libs, so when doing a parallel install
  26         # of the modules and libs breaks during relinking.  Force the libs to
  27         # install first, and then the modules that use those libs.  #488126
  28         echo "install-modexecLTLIBRARIES: install-libLTLIBRARIES" >> Makefile.in
  29 }
  30
  31 src_configure() {
  32         use custom-cflags || strip-flags
  33         ac_cv_lib_bz2_BZ2_bzBuffToBuffDecompress=$(usex bzip2) \
  34         econf \
  35                 $(use_enable bzip2 cckd-bzip2) \
  36                 $(use_enable bzip2 het-bzip2) \
  37                 $(use_enable suid setuid-hercifc) \
  38                 --enable-custom="Gentoo ${PF}.ebuild" \
  39                 --disable-optimization
  40 }
  41
  42 src_install() {
  43         default
  44         insinto /usr/share/hercules
  45         doins hercules.cnf
  46         dodoc README.* RELEASE.NOTES
  47         dohtml -r html
  48 }