app-emulation/ganeti-instance-image/ganeti-instance-image-0.6-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 if [[ ${PV} == "9999" ]]; then
   7         EGIT_REPO_URI="git://git.osuosl.org/${PN}.git"
   8         EGIT_BRANCH="master"
   9         inherit git-r3 autotools
  10 else
  11         SRC_URI="http://ftp.osuosl.org/pub/osl/ganeti-instance-image/${P}.tar.gz"
  12 fi
  13
  14 DESCRIPTION="Scripts to build out CD or image based VMs using Ganeti"
  15 HOMEPAGE="http://code.osuosl.org/projects/ganeti-image"
  16
  17 LICENSE="GPL-2"
  18 SLOT="0"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE=""
  21
  22 DEPEND=""
  23 RDEPEND="app-arch/dump
  24         >=app-emulation/ganeti-2.15.2-r7
  25         app-emulation/qemu
  26         sys-apps/util-linux
  27         sys-fs/multipath-tools
  28         sys-fs/e2fsprogs"
  29
  30 src_prepare() {
  31         default
  32         if [[ ${PV} == "9999" ]]; then
  33                 eautoreconf
  34         fi
  35 }
  36
  37 src_configure() {
  38         econf --with-default-dir=/etc/ganeti
  39 }
  40
  41 src_install() {
  42         emake DESTDIR="${D}" install
  43
  44         rm -rf "${D}"/usr/share/doc/${PN}
  45         dodoc README.markdown NEWS ChangeLog
  46         insinto /etc/ganeti
  47         newins defaults ${PN}
  48 }