app-emulation/fuse/fuse-1.5.6.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 DESCRIPTION="Free Unix Spectrum Emulator by Philip Kendall"
   7 HOMEPAGE="http://fuse-emulator.sourceforge.net"
   8 SRC_URI="mirror://sourceforge/fuse-emulator/${P}.tar.gz"
   9
  10 LICENSE="GPL-2+"
  11 SLOT="0"
  12 KEYWORDS="~amd64 ~ppc ~x86"
  13 IUSE="alsa ao backend-fbcon backend-sdl backend-svga backend-X gpm joystick memlimit png xml"
  14
  15 # Only one UI back-end can be enabled at a time
  16 REQUIRED_USE="?? ( backend-fbcon backend-sdl backend-svga backend-X )"
  17
  18 RDEPEND="
  19         >=app-emulation/libspectrum-1.4.4
  20         dev-libs/glib:2
  21         alsa? ( media-libs/alsa-lib )
  22         ao? ( media-libs/libao )
  23         backend-sdl? ( media-libs/libsdl )
  24         backend-svga? ( media-libs/svgalib )
  25         backend-X? ( x11-libs/libX11 x11-libs/libXext )
  26         !backend-fbcon? ( !backend-sdl? ( !backend-svga? ( !backend-X? ( x11-libs/gtk+:3 ) ) ) )
  27         gpm? ( sys-libs/gpm )
  28         joystick? ( media-libs/libjsw )
  29         png? ( media-libs/libpng:0= sys-libs/zlib )
  30         xml? ( dev-libs/libxml2:2 )"
  31 DEPEND="${RDEPEND}
  32         backend-fbcon? ( virtual/linux-sources )
  33         dev-lang/perl
  34         virtual/pkgconfig"
  35
  36 DOCS=( AUTHORS ChangeLog README THANKS )
  37
  38 src_configure() {
  39         local myconf=(
  40                 --without-win32
  41                 $(use_with alsa)
  42                 $(use_with ao libao)
  43                 $(use_with gpm)
  44                 $(use_with joystick)
  45                 $(use_enable joystick ui-joystick)
  46                 $(use_enable memlimit smallmem)
  47                 $(use_with png)
  48                 $(use_with xml libxml2)
  49         )
  50
  51         if use backend-sdl; then
  52                 myconf+=("--with-sdl")
  53         elif use backend-X; then
  54                 myconf+=("--without-gtk")
  55         elif use backend-svga; then
  56                 myconf+=("--with-svgalib")
  57         elif use backend-fbcon; then
  58                 myconf+=("--with-fb")
  59         else
  60                 myconf+=("--with-gtk")
  61         fi
  62
  63         econf "${myconf[@]}"
  64 }
  65
  66 src_test() {
  67         emake test
  68 }